¿Cómo alternar con escala de grises en Yosemite?

El siguiente código de AppleScript de ejemplo cambiará el estado de la casilla de verificación "Usar escala de grises" en Accesibilidad en Preferencias del sistema en OS X Yosemite (probado en 10.10.4) independientemente de lo que se seleccionó por última vez en Accesibilidad, ya que le dice a Preferencias del sistema que abra directamente a la ubicación de la casilla de verificación "Usar escala de grises" y cambiar su estado.

tell application "System Preferences"
    reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
    tell application "System Events" to tell front window of application process "System Preferences"
        with timeout of 5 seconds
            repeat until (exists checkbox "Use grayscale")
                delay 0.1
            end repeat
            click checkbox "Use grayscale"
        end timeout
    end tell
    quit
end tell

El siguiente problema es cómo quieres ejecutarlo. El problema que rodea a configurarlo como un Servicio a través de Automator para usar un método abreviado de Teclado sin el uso de una utilidad de terceros es que cada aplicación que reciba la combinación de teclas de método abreviado deberá tener permiso para hacerlo y eso se convierte en una molestia a menos que solo elija, por ejemplo. Buscador en lugar de todas las aplicaciones. Entonces, sin una utilidad de terceros, lo guardaría como un script en la carpeta Script de Usuarios y luego accedería al mismo desde el menú Script en la barra de menú de Apple o como una aplicación.

Las configuraciones para el menú de Script en la barra de menú de Apple están en las Preferencias de los Editores de Script. Luego solo son dos clics del mouse cada vez que desee cambiar el estado de la casilla de verificación "Usar escala de grises". Uno para hacer clic en el menú Scripts y otro para hacer clic en el nombre del script.

Como una aplicación, puede colocarse en el Dock y luego hacer clic con el mouse en cualquier momento que desee para cambiar el estado de la casilla de verificación "Usar escala de grises".

En cualquiera de estos dos casos, deberá otorgar un permiso en Accesibilidad en la pestaña Privacidad de Seguridad y amp; Privacidad en las Preferencias del Sistema para ejecutarlo con éxito.

Como nota al margen, si usa un programa como FastScripts , solo necesita usar el ejemplo AppleScript código como .scpt guardado en Editor de secuencias de comandos , no cree un Automator service utilizando la solución mencionada en el comentario y puede asignar el método abreviado de teclado en Preferencias para FastScripts .

_{Tenga en cuenta que no estoy afiliado con el desarrollador de FastScripts, solo un usuario satisfecho.}

Encontré un Discusión de Apple acerca de esto y el usuario que respondió la pregunta ha publicado un archivo AppleScript que se encenderá y apagará en escala de grises. He modificado el código original para que funcione con OS X Yosemite.

Abra el "Editor de secuencias de comandos" y, en un nuevo documento, pegue lo siguiente:

tell application "System Preferences" to activate
delay 1

tell application "System Events"
tell process "System Preferences"
click the menu item "Accessibility" of the menu "View" of menu bar 1
delay 0.5
click the checkbox "Use grayscale" of window "Accessibility"
end tell
end tell
tell application "System Preferences" to quit

Haz clic en el martillo para compilarlo y luego guarda, pero donde dice "Formato de archivo" en el cuadro de diálogo de guardar, elige "Aplicación"

Antes de ejecutar este código, asegúrese de que se haya seleccionado "Mostrar" en Accesibilidad como la imagen a continuación. Una vez hecho esto, puedes salir de Preferencias del Sistema.

En la primera ejecución de la aplicación, se bloqueará y OS X le preguntará si desea permitir que la aplicación controle la computadora mediante las funciones de accesibilidad. Permitir el acceso, salir de la aplicación y relanzarla.

A veces esto no funcionará y se bloqueará con un mensaje de error. Si esto sucede, simplemente vuelva a iniciarlo y funcionará bien.

EDITAR: Esto puede ayudarlo a convertirlo en un método abreviado de teclado: Enlace

Utilicé el script de @CreeperzEdge answer y tuve un poco de retraso en mi computadora. He cambiado ligeramente el script a:

tell application "System Preferences" to reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
tell application "System Preferences"
    activate
    tell application "System Events" to tell process "System Preferences"
        click the checkbox "Use grayscale" of window "Accessibility"
    end tell
end tell

tell application "System Preferences" to quit

De alguna manera

tell application "System Preferences" to reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"

es más rápido que

tell application "System Preferences"
    activate
    reveal anchor "Seeing_Display" of pane id "com.apple.preference.universalaccess"
end tell

Me gustaría saber la experiencia de otros.

Encontré que se necesitaba un retraso de 1 segundo para que funcionara para mí.

tell application "System Preferences"
    activate
    reveal anchor "Seeing_Display" of pane "com.apple.preference.universalaccess"
    delay 1
    tell application "System Events" to tell process "System Preferences"
        click the checkbox "Use grayscale" of window "Accessibility"
    end tell
end tell
tell application "System Preferences" to quit

He creado una aplicación para facilitar este proceso. Le permite alternar la visualización en escala de grises desde la barra de estado. Es una envoltura alrededor del AppleScript mencionado en las respuestas escritas usando PyObjC. Lo he probado para trabajar en macOS Mojave.

Puede descargarlo desde aquí . El código fuente está aquí .

Nota : debido a las restricciones de Apple, la aplicación necesita tres tipos de permisos para funcionar: a) permite abrir una aplicación de un desarrollador no identificado b) permite acceder a los Eventos del Sistema. c) Permisos de accesibilidad.