¿Cómo muestra solo álbumes completos en iTunes 11?

No hay manera de hacer eso, por desgracia. Esta sugerencia muestra un AppleScript que puede hacer listas de reproducción de todos los álbumes completos, pero si tienes muchos álbumes. , podría ser abrumador.

Haga una lista de reproducción inteligente con el siguiente filtro: los comentarios contienen el Álbum completo. Para cada álbum que quiero agregar, hago clic en Obtener información y agrego Álbum completo al campo de comentarios

No puedes. Escribe una sugerencia a Apple en: enlace

Puede crear una lista de reproducción que contenga todos los álbumes completos en su biblioteca usando AppleScript. El código a continuación es solo una pequeña modificación del guión vinculado en la respuesta de Kirk para que cree una lista de reproducción en lugar de una por álbum. Es lento (tarda aproximadamente 5 minutos en ejecutarse en mi biblioteca) y es muy sensible a cualquier inexactitud de metadatos, pero funciona para mí.

-- Creates one playlist of all full albums you have in iTunes
-- Set the playlistPrefix and playlistSuffix as desired before running

-- Original script by duozmo on Ask Different
-- http://hints.macworld.com/article.php?story=20130201061128257
-- http://apple.stackexchange.com/a/77626

-- Based on code by Brad Campbell
-- http://www.bradcampbell.com/2009/05/26/make-a-whole-album-playlist-in-itunes/

tell application "iTunes"
    set albumPlaylistName to "Full Albums"
    -- Create playlist
    if user playlist albumPlaylistName exists then
        try
            delete tracks of user playlist albumPlaylistName
        end try
    else
        make new user playlist with properties {name:albumPlaylistName}
    end if

    set albumBuckets to {} as list
    set allSongs to (every track of library playlist 1 whose enabled is true and podcast is false and kind contains "audio") as list

    -- Find all partial albums in iTunes
    repeat with currentTrack in allSongs
        set albumName to album of currentTrack as text
        set artistName to artist of currentTrack as text

        -- First check for missing values, then perform integer comparison
        -- Zero is on the left to force interger type coercion, just in case
        if album of currentTrack is not missing value and 0 is less than length of albumName then
            if artist of currentTrack is not missing value and 0 is less than length of artistName then
                if track number of currentTrack is not missing value and 0 is less than track number of currentTrack then
                    if track count of currentTrack is not missing value and 0 is less than track count of currentTrack then
                        if albumBuckets does not contain album of currentTrack then
                            copy album of currentTrack to the end of albumBuckets
                        end if
                    end if
                end if
            end if
        end if

    end repeat

    repeat with currentAlbum in albumBuckets
        set albumSongs to (every track of library playlist 1 whose album is currentAlbum)
        set firstTrack to first item of albumSongs

        -- Filter album list to act only on full albums
        if (count of albumSongs) is equal to track count of first item of albumSongs and 1 is less than (count of albumSongs) then
            -- This is a full album, construct the playlist

            -- Sort tracks by track number
            set albumSongsSorted to {} as list
            repeat with i from 1 to (count of albumSongs)
                repeat with trk in albumSongs
                    if track number of trk is i then
                        set nextSong to trk
                        copy nextSong to the end of albumSongsSorted
                    end if
                end repeat
            end repeat

            try
                repeat with trk in albumSongsSorted
                    duplicate trk to user playlist albumPlaylistName
                end repeat
            end try
        end if
    end repeat

    display dialog albumPlaylistName & " playlist created!"
end tell

Otra opción sería usar el script Álbumes completos aleatorios de Doug si solo quieres que iTunes Actúa como un cambiador de CD en el modo de reproducción aleatoria del álbum.