Crear un nuevo archivo (.txt) en Finder - Atajo de teclado

Bueno, aquí tienes un AppleScript para eso.

Primero, crea el AppleScript:

1. Open Automator
2. Crear un Servicio
3. Establezca la entrada en sin entrada
4. Arrastre y suelte el elemento de flujo de trabajo Ejecutar AppleScript en el espacio gris.
5. Pegue el código de abajo en AppleScript
6. Guarde el flujo de trabajo como Crear nuevo archivo
   Si tienes activado iCloud Drive, asegúrate de guardar el archivo en Library/Services/ en tu carpeta de inicio.

try
  tell application "Finder" to set the this_folder ¬
   to (folder of the front window) as alias
on error -- no open folder windows
  set the this_folder to path to desktop folder as alias
end try

set thefilename to text returned of (display dialog ¬
 "Create file named:" default answer "filename.txt")
set thefullpath to POSIX path of this_folder & thefilename
do shell script "touch \"" & thefullpath & "\""

Para agregarlo como acceso directo:

• Ir a Configuración - > Teclado - > Accesos directos - > Servicios
• Desplácese hacia abajo hasta que encuentre el Servicio Crear nuevo archivo
• Asígnele un acceso directo haciendo clic en el lado derecho ninguno , que se convierte en un Añadir acceso directo .
  Haga clic en el botón y escriba el acceso directo que desea utilizar.
  Uso ⌘ Comando + ⌥ Opción + N

He creado un AppleScript muy similar al de @YoshiBotX, pero con algunas mejoras.

La idea es crear un flujo de trabajo de Automator y asignarle un acceso directo mediante los siguientes pasos:

• Abre Automator y crea un Servicio ;
• Establezca la entrada en sin entrada y la aplicación en Finder.app ;
• Arrastre y suelte el elemento de flujo de trabajo Ejecutar AppleScript en el espacio gris;
• Coloque el contenido de este AppleScript en el cuadro de texto;
• Guarde el flujo de trabajo con un nombre razonable (como Nuevo archivo );
• Vaya a Configuración - > Teclado - > Accesos directos - > Servicios y asignarle un acceso directo.

Ahora, vamos a mostrar el AppleScript:

set file_name to "untitled"
set file_ext to ".txt"
set is_desktop to false

-- get folder path and if we are in desktop (no folder opened)
try
    tell application "Finder"
        set this_folder to (folder of the front Finder window) as alias
    end tell
on error
    -- no open folder windows
    set this_folder to path to desktop folder as alias
    set is_desktop to true
end try

-- get the new file name (do not override an already existing file)
tell application "System Events"
    set file_list to get the name of every disk item of this_folder
end tell
set new_file to file_name & file_ext
set x to 1
repeat
    if new_file is in file_list then
        set new_file to file_name & " " & x & file_ext
        set x to x + 1
    else
        exit repeat
    end if
end repeat

-- create and select the new file
tell application "Finder"

    activate
    set the_file to make new file at folder this_folder with properties {name:new_file}
    if is_desktop is false then
        reveal the_file
    else
        select window of desktop
        set selection to the_file
        delay 0.1
    end if
end tell

-- press enter (rename)
tell application "System Events"
    tell process "Finder"
        keystroke return
    end tell
end tell

Para mayor comodidad, coloco este AppleScript en este GitHub Gist .

Usted puede crear un Servicio Automator usted mismo, es bastante simple de hacer. Luego, puede asignarle un método abreviado de teclado para que no tenga que activar el servicio a través del menú de servicios (que puede hacer de todos modos).

Abra Automator y seleccione Servicio como el tipo de documento nuevo.

Configure el servicio para que no reciba ninguna entrada en Finder.app y agregue la acción Nuevo documento de edición de texto al flujo de trabajo.

Guardeelservicio,luegoabraPreferenciasdelsistema→Teclado→Accesosdirectos→ServiciosdondeencontraráelserviciolistadoenGeneralconelnombrequeledioalserviciocuandologuardó.

Agregue un atajo de teclado al servicio seleccionando el servicio y luego haciendo clic en 'agregar atajo'.

Aquí puede tener algunos problemas si el acceso directo ya está en uso. Así que sé creativo para hacer uno que funcione para ti.

También puede asignar un acceso directo a un script como este:

tell application "Finder"
    set selection to make new file at (get insertion location)
end tell

La ubicación de inserción es el destino de la ventana del Buscador frontal o el escritorio.

abre el terminal y escribe

touch filename

o

> filename

Esta es una publicación de una publicación que hice el año pasado. He tenido una buena experiencia con lo siguiente.

Hay dos utilidades útiles que puedes descargar e instalar que te permitirán crear un nuevo archivo de texto (o archivo RTF) en una carpeta actualmente abierta que estás viendo usando el Finder.

Las utilidades se denominan NewTextFileHere y NewRTFHere y se pueden descargar desde

enlace

Los iconos de cualquiera de estas aplicaciones se pueden incluir en todas las ventanas del Finder.

Justo lo que había estado buscando, Richard Fuhr. Gracias por esto.

Una nota: el enlace de la URL para NewTextFileHere parece cargarse en una página vacía. Pero hice una búsqueda y encontré la aplicación aquí: enlace

Una alternativa, si ya tiene BetterTouchTools (solía ser una aplicación gratuita, ahora tiene un sistema de pago por uso). (si desea un modelo con un período de prueba de 30 días), puede encontrar la acción en "Utility Actions > Create New File in Current Folder" que hace exactamente esto, con una ventana emergente que le permite elegir el nombre. Asigna el acceso directo que desees (elegí Opción + Mayús + N) y listo.

En caso de que esté utilizando MacVim , hay una opción en Finder -> Services para crear un nuevo búfer vim:

HeasignadoestoalaccesodirectoShiftcmdMenSystemPreferences->Keyboard->Shortcuts: