Mac Sierra - Conversión por lotes de páginas a texto sin formato

Question

Mac Sierra - Conversión por lotes de páginas a texto sin formato

#1 de jackjr300 (2 votos)

4

Intento convertir por lotes las páginas a texto sin formato, pero sigo teniendo problemas con los permisos de archivos. (Usando Sierra 10.2.3 después de actualizar desde 10.2.2)

el nombre de archivo no se pudo exportar. No tienes permiso.

Dos métodos hasta ahora:

on run
    tell application "Finder"
        set mfolder to "Macintosh HD:Users:me:Documents:convertme:"
        set theFiles to name of every file of folder mfolder
    end tell
    set theFolder to "Macintosh HD:Users:me:Documents:converted:"
    tell application "Pages"
        activate
        repeat with aFile in theFiles
            open aFile
            set sourceFolder to POSIX path of aFile
            set newsourceFolder to characters 1 thru -8 of sourceFolder as string
            set theFolder to newsourceFolder & ".txt"
            export front document to POSIX file theFolder as unformatted text
            close front document
        end repeat
    end tell
end run

También se probó con Automator: en Solicitar elemento del buscador

function run(input, parameters) {
    inFile  = Path( input );
    outFile = Path( input.toString().replace(/\.[^\.]+$/, '.pdf') );
    pages    = Application('Pages');
    document = pages.open( inFile );
    pages.export(document, {to: outFile, as: 'PDF'});
    pages.close(document, {saving: 'no'});
    return outFile;
}

Permisos en la carpeta configurados para: todos leen y escriben

applescript sierra automator pages

pregunta ina 06.02.2017 - 15:16

1 respuesta

Lea otras preguntas en las etiquetas applescript sierra automator pages

¿Cómo puedo instalar GDB en NetBeans en Mavericks para la depuración? Mis reglas de correo no se quedan

score 2 · Accepted Answer

Este script funciona para mí, probado en MacOS Sierra y Páginas Versión 6.0.5

set mfolder to "Macintosh HD:Users:me:Documents:convertme:"
set destFolder to "Macintosh HD:Users:me:Documents:converted:"

tell application "Finder" to set theNames to name of files of folder mfolder

tell application "Pages"
    repeat with aName in theNames
        set theDoc to open ((mfolder & aName) as alias)
        set newFile to destFolder & (text 1 thru -7 of aName) & ".txt" -- concat destFolder and the name without the ".pages" extension 
        my makenewFile(newFile)

        export theDoc to file newFile as unformatted text
        close theDoc
    end repeat
end tell

on makenewFile(thePath)
    close access (open for access thePath)
    -- delay 0.5 -- use the delay command, If you still have a permission issue,  increase the number of seconds
end makenewFile