Lote abrir archivos JPG en Vista previa

Navega tus respuestas
3

Ya he echado un vistazo en los foros para encontrar una respuesta al problema, pero la mayoría de las veces es en el contexto de archivos de conversión por lotes (con nombres dispares). Solo quiero abrir un rango de archivos JPEG en Vista previa.

Capturo imágenes de artículos particulares en mi taller usando "Workflow" para iOS. Tiene un script propio que guarda los archivos en el formato 00000-0.JPG donde los primeros cinco ceros son el número del artículo y el último cero es el orden secuencial de ese elemento particular. Por ejemplo, 78934-4.JPG es la cuarta foto del artículo "78934". El número de imágenes para un artículo dado puede variar mucho.

Todos estos terminan en una carpeta (en mi Mac) con varios miles de otras imágenes, todas con la misma convención de nomenclatura. Me gustaría acelerar el proceso de búsqueda y apertura de estos (como estar en Finder, seleccionar un rango de imágenes a mano y hacer doble clic en el rango y hacer que se abran en una "instancia" o ventana de Vista previa - para minimizar el tener para arrastrar ventanas sobre) con AppleScript.

Esto es lo que he escrito hasta ahora ... 

tell application "Finder" to set myFiles to folder "Macintosh SSD:Users:me:ownCloud:Bilder_neu:Einzelbilder"

set file_extention to ".JPG"

set articleNumber to display dialog "Please enter article number" default answer "" with icon note buttons {"Cancel", "Continue"} default button "Continue"

No estoy seguro de cómo administrar el "for loop" para encontrar y luego abrir las imágenes.

Gracias por la ayuda prestada

    
pregunta William Lombard 02.02.2018 - 10:30

2 respuestas

1

El siguiente ejemplo AppleScript código asume que el macOS predeterminado de imágenes la apertura en Vista previa todavía está en juego. 

set theImages to quoted form of POSIX path of ¬
    ((path to home folder as string) & "ownCloud:Bilder_neu:Einzelbilder")

set articleNumber to text returned of ¬
    (display dialog "Please enter article number:" default answer ¬
        "" with icon note buttons {"Cancel", "Continue"} default button "Continue")

do shell script "find " & theImages & " -type f -iname '" & articleNumber & "-*.JPG' -exec open {} +"

Si Vista previa no es el controlador predeterminado para los archivos de imagen, cambie el comando do shell script a: 

do shell script "open -a Preview $(find " & theImages & " -type f -iname '" & articleNumber & "-*.JPG')"

Tenga en cuenta que " pure AppleScript" no es necesario.

Nota: El ejemplo AppleScript código es solo eso y no emplea ningún manejo de errores y está destinado solo a mostrar una de las muchas maneras en que se puede realizar una tarea. La responsabilidad recae siempre sobre el Usuario para agregar / usar el manejo de errores según sea necesario / deseado.

    
respondido por el user3439894 02.02.2018 - 12:27
0

Este es un medio puro de AppleScript para lograr tu objetivo: 

set ImagesFolder to "/Users/me/ownCloud/Bilder_neu/Einzelbilder"

set articleNumber to text returned of (display dialog ¬
    "Please enter article number" default answer ¬
    "" with icon note buttons {"Cancel", "Continue"} ¬
    default button "Continue")

tell application "System Events" to set JPGs to ¬
    path of every file in folder ImagesFolder whose ¬
    type identifier is "public.jpeg" and ¬
    name begins with (articleNumber & "-")

tell application "Preview" to open JPGs
    
respondido por el CJK 02.02.2018 - 13:40

Lea otras preguntas en las etiquetas

Forzar una aplicación a la siesta ¿Cambiar el rango de volumen para el sonido? (es decir, rango de dB para el control deslizante)