He encontrado un camino a través de BetterTouchTool para hacer lo siguiente:

• Activar el Visor del teclado mediante un acceso directo
• Cierre el Visor del teclado con otro acceso directo
• Alternar el Visor del teclado mediante un acceso directo (no es necesario para los dos anteriores)
• También subí el AppleScript para mayor comodidad

Plataforma: rMBP Mountain Lion OSX 10.8

Activar el Visor del teclado mediante un acceso directo

• Ejecutar BetterTouchTool
• Agregar método abreviado de teclado
• Agregar acción predefinida > > Abrir aplicación / archivo / script ...
• Navegue a Macintosh HD / System / Library / Input Methods /
• Seleccionar KeyboardViewer

Ahora tiene un método abreviado de teclado para activar el visor sin un script adicional.

SIN EMBARGO, noté que al presionar el botón rojo X no se cierra la aplicación, lo que significa que el visor de teclado solo se activará una vez. Así que necesitas crear un script para salir del programa.

Para solucionar este problema:

Cerrar el Visor de teclado con otro método abreviado de teclado

• Open Automator
• Elegir aplicación como tipo de documento
• Agregar RunAppleScript
• Donde dice (* Tu script va aquí *), reemplázalo con quit application "KeyboardViewer"
• Compile y guarde como en los documentos o en cualquier lugar que desee (lo moví a la misma ubicación que KeyboardViewer)
• Abre BetterTouchTool
• Agregar método abreviado de teclado
• Agregar acción predefinida > > Abrir aplicación / archivo / script ...
• Localice el archivo de la aplicación que acaba de guardar

Ahora tiene una forma de salir del visor de KeyBoard para siempre una vez que esté activado. Úsalo en lugar del botón X rojo. Hasta que descubra por qué el visor del teclado no se cierra completamente cuando presionas el botón X, esta debería ser tu solución.

EDIT

¡He descubierto una manera de cambiar el visor del teclado!

TOGGLE KEYBOARD VIEWER con un atajo de teclado

el mismo proceso que antes, pero se cambia el código:

• Open Automator
• Elegir aplicación como tipo de documento
• Agregar RunAppleScript
• Donde dice (* Su script va aquí *), reemplácelo con

  if application "KeyboardViewer" is running then
      quit application "KeyboardViewer"
  else
      activate application "KeyboardViewer"
  end if

• Compile y guarde como en los documentos o en cualquier lugar que desee (lo moví a la misma ubicación que KeyboardViewer)
• Abre BetterTouchTool
• Agregar método abreviado de teclado
• Agregar acción predefinida > > Abrir aplicación / archivo / script ...
• Localice el archivo de la aplicación que acaba de guardar

Ahora el Visor del teclado está activado y ¡ni siquiera es necesario asignar varios accesos directos!

Enlace para AppleScript

Subí la aplicación en línea para un acceso más rápido en lugar de hacer todos los pasos de codificación anteriores (solo activa esta aplicación a través de BetterTouchTool) Sin embargo, como no soy un editor identificado, su sistema operativo puede bloquear la ejecución de esta aplicación, dependiendo de sus preferencias de seguridad. Entonces, si prefiere no ejecutar aplicaciones de editores no identificados, simplemente siga los pasos anteriores para crear su propia aplicación.

Enlace a archivo: enlace

Espero que ayude a alguien como me ayudó :)

Inicie Keyboard Viewer con un servicio (mejorado)

Puede iniciar Keyboard Viewer con un acceso directo utilizando Automator y la funcionalidad de OS X Services.

El programa Keyboard Viewer vive en /System/Library/Input Methods/KeyboardViewer.app (en versiones anteriores a Lion, puede estar en /System/Library/Components/KeyboardViewer.component/Contents/SharedSupport/KeyboardViewerServer.app ). Se abre con una tecla de acceso rápido utilizando Automator para crear un servicio de inicio simple.

1. Abra Automator y seleccione Servicio como el tipo de su nuevo documento.
2. Establezca las opciones (en la parte superior del área de flujo de trabajo) en "El servicio no recibe ninguna entrada en ninguna aplicación ".

3. Agregue la acción Ejecutar AppleScript a su flujo de trabajo y reemplace el texto con las siguientes líneas:

   if application "KeyboardViewer" is running then
       quit application "KeyboardViewer"
   end if
   
   activate application "KeyboardViewer"
   
   -- wait until the window has been closed, then end the KeyboardViewer process
   set numberOfWindows to 1
   repeat until numberOfWindows = 0
       delay 5
       tell application "System Events"
           tell process "KeyboardViewer"
               set numberOfWindows to count windows
           end tell
       end tell
   end repeat
   quit application "KeyboardViewer"
   

4. Guardar con un nombre como "Abrir Visor de teclado", luego abra Preferencias de teclado en la pestaña Atajos de teclado . Seleccione Servicios en el panel izquierdo y desplácese hasta la parte inferior, donde debería ver el nombre de su Servicio en la Sección General.
5. Asegúrese de que la casilla esté marcada para habilitarla, luego selecciónela y haga clic en agregar acceso directo para configurar una tecla de acceso rápido.
6. Después de configurar la tecla de acceso rápido, abra el menú Servicios en cualquier aplicación (es decir, Finder > Servicios), luego ciérrelo. Por alguna razón, mi tecla de acceso rápido no funcionó hasta que hice esto.

Un par de notas:

• La secuencia de comandos requiere que marque la casilla Habilitar acceso para dispositivos de asistencia en el panel de preferencias de Acceso universal .
• Cerrar la ventana del Visor del teclado en realidad no cierra la aplicación, y como señala Lri, puede ser un asco de recursos, por lo que el bucle repeat comprueba cada 5 segundos si el Visor del teclado tiene ventanas abiertas y si no, abandona el proceso.
• Si está ejecutando un sistema operativo anterior a Lion, puede necesitar reemplazar las instancias de KeyboardViewer con KeyboardViewerServer . No tengo nada antes de que Lion esté a la mano para probar esto (si alguien más pudiera informar en los comentarios, sería genial.
• Debido a que el script se desplaza hasta que se cierra el Visor del teclado, el icono del engranaje giratorio del Automator se mostrará en la barra de menú hasta que se cierre.

El Extra Scripts Plugin de Quicksilver ofrece esta funcionalidad al proporcionar Show Keyboard Viewer.scpt .

Además, cuando crea un activador Quicksilver para Mostrar Keyboard Viewer.scpt con la acción Ejecutar , obtiene la tecla de acceso rápido del Visor de teclado global.

Aquí está la fuente del script:

property theApplication : "KeyboardViewer"
property thePath : "/System/Library/Input Methods/KeyboardViewer.app"

set HFSPath to ((POSIX file thePath) as string)
tell application "System Events" to ¬
    set isRunning to 0 < (count (application processes whose name is theApplication))
if isRunning then
    tell application HFSPath to quit
else
    ignoring application responses
        tell application HFSPath to activate
    end ignoring
end if

Si KeyboardViewer se abre con un AppleScript o con open y la ventana principal se cierra, el proceso de Keyboard Viewer permanece abierto y sigue usando alrededor de 0-20% de CPU.

Me alegro de haber encontrado este hilo. Basándome en las respuestas anteriores, hice un script de extensión Alfred que cambia el Visor del teclado.

enlace

Proporciona una palabra clave alfred "kv" que activa y desactiva el Visor de teclado al ejecutar el siguiente script de manzana:

-- adapted from http://apple.stackexchange.com/a/62532
if application "KeyboardViewer" is running then
    quit application "KeyboardViewer"
else
    activate application "KeyboardViewer"
end if

(*
-- adapted from http://apple.stackexchange.com/a/59986
tell application "System Events" to tell process "SystemUIServer"
    tell (menu bar item 1 where description is "text input") of menu bar 1
        click
        click (menu item 1 where title ends with "Keyboard Viewer") of menu 1
    end tell
end tell
*)
-- icon ripped from osx /System/Library/PreferencePanes Keyboard.prefPane/Contents/Resources/Keyboard.icns

Dejé una implementación alternativa comentada, en caso de que tenga problemas de rendimiento que debía evitar.

Esto también funcionaría después de cerrar la ventana principal al hacer clic en el botón de cerrar:

if application "KeyboardViewer" is running then
    tell application "System Events" to number of windows of process "KeyboardViewer"
    if result is 0 then
        quit application "KeyboardViewer"
        delay 0.1
        launch application "KeyboardViewer"
    else
        quit application "KeyboardViewer"
    end if
else
    launch application "KeyboardViewer"
end if

Si el Visor del teclado se abre con AppleScript o open -a KeyboardViewer y la ventana principal se cierra, el proceso permanece abierto y sigue usando alrededor de 0-15% de CPU. No sucede cuando se selecciona Mostrar Visor del teclado desde el menú de entrada. Entonces, una mejor opción podría ser hacer clic en el elemento del menú:

tell application "System Events" to tell process "SystemUIServer"
    tell (menu bar item 1 where description is "text input") of menu bar 1
        click
        click (menu item 1 where title ends with "Keyboard Viewer") of menu 1
    end tell
end tell

Ambos scripts requieren acceso para que los dispositivos de asistencia estén habilitados en el panel de preferencias de accesibilidad.

No es un método abreviado de un solo trazo, pero una solución "sin ratón" es Fn + Ctrl + F8 para enfocar los iconos " Menú de estado " en el lado derecho de la barra de menús. ( Sección 4 )

LasflechaslollevaránaliconodePreferenciasdeltecladoylasopcionesMostrar/Ocultar.CuandoingresaFn+Ctrl+F8elíconoenelladoizquierdomásalejadodelosíconosdel"Menú de estado" que están en la mitad derecha de La barra de menú se resaltará. Una vez que esté seleccionado, use la Flecha derecha → para navegar a la que desea. Use la Flecha abajo ↓ para abrir el menú y seleccionar la opción que desee. Tenga en cuenta que la tecla Opción hará que diferentes opciones de menú estén disponibles en algunos de los "menús de estado".

Nota,Fn+Ctrl+F2activaráelíconodelmenúAppleenelladoizquierdo.Desdeallí,laFlechaderecha→ledaráaccesoalmenúdelaaplicación.EstasopcionesestándisponiblesenPreferenciasdelsistema>>Teclado>>Atajos::Teclado:

Dependiendodecómohayaconfiguradosusteclasdefunción,Fnesopcional.

EnmacOSSierratambiénpuedesusarSiriparaayudarconesto.InvoqueSiriconcualquiermétodoabreviadodetecladoqueelijaenPreferenciasdelsistema>>Siri::Métodoabreviadodelteclado,porejemplo,Opción+Barraespaciadora

...luegodiga"Encender el visor de teclado"

...yvoila:

Lamentablemente, Siri no cerrará el Visor del teclado, ni Command⌘+w

puedes hacer todo por Automator:

1. abre Automator y selecciona "Aplicación"
2. en la parte superior de la Biblioteca, encuentra "Iniciar aplicación", haz doble clic en ella
3. elija "otro" y navegue hasta el archivo de KeyboardViewer en / System / Library / Input Methods
4. Guarde con un nombre como "iniciar teclado". pruébalo.

La siguiente parte es cerrar el teclado:

1. abre Automator y selecciona "Aplicación"
2. en la parte superior de la Biblioteca, encuentra "Salir de la aplicación", haz doble clic en ella

3. elija "otro" y navegue hasta el archivo de KeyboardViewer en / System / Library / Input Methods

4. Guarde con un nombre como "Salir del teclado". pruébalo.

ahora tendrás dos archivos uno para abrir, uno para cerrar.

¡todo lo que necesita es asociar los botones del mouse para iniciar estos dos archivos!

por ejemplo, estoy usando Microsoft Bluetooth Notebook Mouse 5000 y se

funciona muy bien para mí en 10.9.1

Monitor de actividad, KeyboardViewer.app se inicia desde

Ubicación del buscador: / Sistema / Biblioteca / Métodos de entrada / KeyboardViewer.app .

Uso normal: abra desde Barra de menús , cierre desde el mouse para ver los botones de la ventana donde se puede hacer clic en el botón (x) close . Para habilitar el panel Barra de menú , Preferencias del sistema , Teclado , Teclado , seleccione Mostrar teclado y Emoji Visores en la barra de menú .

El applet KeyboardViewer exhibe comportamientos restrictivos.

1. La ventana del applet no responde a ⌘-Q , ⌘-W .
2. Curiosamente, cuando se abre desde la carpeta Métodos de entrada , luego el Monitor de actividad muestra que el applet sigue funcionando después de que se cierre su ventana.
3. El Automator AppleScript que se muestra a continuación se ejecuta lentamente en segundo plano, los servicios de teclado tardan unos segundos en registrar las acciones de apertura y cierre en el Monitor de actividad.
4. El script de acceso directo del teclado que se muestra a continuación se ejecuta sin errores, pero el sistema parece ignorarlo.
5. Quit Application de Sierra Automator no cerrará KeyboardViewer.app

El siguiente script de Automator se puede guardar como una aplicación para abrir-cerrar KeyboardViewer.app con un solo clic (el Monitor de actividad también muestra esta actividad de abrir y cerrar), y funciona bien cuando se coloca en el muelle.

Automator: Nuevo , Aplicación , Ejecutar AppleScript , guarde este script

-- see above post, Render
    on run {input, parameters}
        if application "KeyboardViewer" is running then
            quit application "KeyboardViewer"
        else 
            activate application "KeyboardViewer"
        end if
        return input
    end run
-- icon /System/Library/PreferencePanes Keyboard.prefPane/Contents/Resources/Keyboard.icns

Lamentablemente, esto no agrega un método abreviado de teclado. Sin embargo, ofrece una solución de un solo clic. Puede haber alguna forma de agregar un método abreviado de teclado usando Automator. Una secuencia de comandos de acceso directo general se parece a esto (pero no está seguro de cómo incorporar).

tell application "System Events"
    set application "KeyboardViewer" to keystroke "K" using control down
end tell

(macOS Sierra 10.12.6 en MP 6,1)