¿Cómo activar manualmente el cambio de imagen de fondo?

Encontré que esta MacWorld publicaba un AppleScript que puedes ejecutar para forzar eso.

  

Tengo mis imágenes de escritorio configuradas para cambiar cada 30 minutos en orden aleatorio. A veces, el escritorio muestra una imagen que se mostró anteriormente en el día, y quería una forma de "avanzar" la imagen fácilmente. El siguiente AppleScript hará que la imagen del escritorio cambie, en el orden que haya establecido, cada vez que se ejecute:

Y este es el script:

property theSwitch : 0
if theSwitch = 0 then
  tell application "System Events"
    tell current desktop
      set change interval to 1801.0
    end tell
  end tell
  set theSwitch to 1
else
  tell application "System Events"
    tell current desktop
      set change interval to 1800.0
    end tell
  end tell
  set theSwitch to 0
end if

Consulte el enlace y los comentarios para ver alternativas más similares o completas.

Nota: No he probado esto.

ACTUALIZACIÓN Lamento escuchar que no funcionó para ti, pero lo hace para mí en Snow Leopard con el siguiente script:

tell application "System Events"
    tell current desktop
        set initInterval to get change interval -- get the currrent display interval
        set change interval to -1 -- force a change to happen right now
        set change interval to initInterval -- change it back to the original display interval
    end tell
end tell

ADVERTENCIA

Esto supone que tienes

[X] "cambiar imagen cada vez x tiempos"

[X] Orden aleatoria

Lo anterior funciona para mí. Lo ejecuté varias veces desde el Editor de AppleScript para asegurarme de que estaba funcionando y de hecho cambia el Fondo de Pantalla.

@ La respuesta de Martín funciona a la perfección en el leopardo de las nieves. Sin embargo, en Lion, cada cambio de change interval da como resultado un cambio de fondo, es decir. el fondo se cambia dos veces cuando se ejecuta el script.

No se preocupe, se arregla fácilmente: simplemente configure change interval como lo que está configurado actualmente para:

tell application "System Events"
    tell current desktop
        set initInterval to get change interval
        set change interval to initInterval
     end tell
end tell

Es un poco tautológico, claro, pero funciona.

Apoloiges por responder a una vieja pregunta.

Gracias a @koiyu por ese código, se confirmó el trabajo en Mountain Lion. Sin embargo, si está utilizando varios monitores, solo funciona en el primer monitor. Modifiqué ligeramente tu código para que funcione en todos los monitores.

tell application "System Events"
    repeat with thisDesktop in every desktop
        tell thisDesktop
            set initInterval to get change interval
            set change interval to initInterval
        end tell
    end repeat
end tell

Curiosamente, si está usando múltiples espacios con el Control de la Misión, solo cambiará los fondos de pantalla en todos los monitores de su espacio enfocado actualmente. Puede cambiar a otro espacio y ejecutarlo nuevamente para cambiar los fondos de pantalla en ese espacio. Espero que esto ayude!