Ejemplo :

set varText to "
This is sentence 1.
This is sentence 2.
This is sentence 3.
This is sentence 4."

set varText to do shell script "sed -e '1d;3d' <<< " & quoted form of varText

Returns:

"This is sentence 1.
This is sentence 3.
This is sentence 4."

Actualización: Como resultado de un descubrimiento mencionado en la Edición: de ¿Cómo eliminar una línea específica de un párrafo basado en" retorno "en AppleScript? , deje Yo hago la siguiente declaración:

NOTA: Lamentablemente, lo que se devuelve en este caso tiene retorno de carro (x0D) caracteres en lugar de la esperada nueva línea (x0A) caracteres y en mi opinión es un error!

Es un error porque: el comando do shell script "sed ..." cuando se ejecuta en Terminal con ese varText devuelve con \n (x0A) no \r (x0D ) como se supone que debe Incluso el comando compilado do shell script "sed ..." en el Editor de secuencias de comandos aún tiene \n (x0A), no \r (x0D), sin embargo, ¿por qué se devuelve con \r (x0D) la intención de la esperada% co_de El% (x0A) es un misterio para mí en este momento y lo consideraré un error de AppleScript, ya que no refleja el comportamiento esperado del mismo cuando se ejecuta en Terminal.

Por lo tanto, para tener en cuenta el error en los resultados del comando \n , así es como lo manejaría. Después del comando do shell script "sed ..." use las siguientes líneas de código :

set newLine to "\n"
set varText to paragraphs of varText
set oldTID to AppleScript's text item delimiters
set AppleScript's text item delimiters to newLine
set varText to varText as string
set AppleScript's text item delimiters to oldTID

Ahora, lo que se devuelve contiene nueva línea (x0A) caracteres como debería haber sido para comenzar si no hubiera este error, no retorno de carro (x0D) caracteres .

Nota: cuando se compila, la línea do shell script "sed ..." de código se mostrará a continuación:

set newLine to "
"

Dividamos este script en partes más pequeñas y luego lo juntemos todo en un AppleScript.

Este enfoque está escrito completamente en AppleScript y no requiere herramientas externas. El uso de herramientas externas, como perl o sed , probablemente dará como resultado soluciones mucho más cortas, pero usted ha mencionado en otras preguntas que desean aprender AppleScript.

1. Dividir con delimitadores

Puede usar el comportamiento de delimitadores de AppleScript para dividir una cadena . Puede cambiar el delimitador como desee a return , linefeed , o incluso caracteres como = :

 -- http://macscripter.net/viewtopic.php?id=24473
 to split(someText, delimiter)
     set AppleScript's text item delimiters to delimiter
     set someText to someText's text items
     set AppleScript's text item delimiters to {""} --> restore delimiters to default value
     return someText
 end split

 set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")
 set myLines to split(myText, return)

2. Lista de filtros

Con la lista devuelta, puede filtrar los elementos no deseados mediante un bucle:

 -- http://macscripter.net/viewtopic.php?id=24525
 set indexesToDelete to {1, 4}
 set cleanList to {}

 repeat with i from 1 to count myLines
     if i is not in indexesToDelete then set cleanList's end to myLines's item i
 end repeat

3. Combina los elementos

La lista filtrada de oraciones se puede volver a combinar usando otro bucle:

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

Enteramente AppleScript

La combinación de estos fragmentos da como resultado el siguiente código:

-- Get the text to work with
set myText to (return & "This is sentence 1." & return & "This is sentence 2." & return & "This is sentence 3." & return & "This is sentence 4.")

-- Split the text into lines based on 'return' delimiter
set myLines to split(myText, return)

-- Filter out indexes 1 and 4 using a loop
set indexesToDelete to {1, 4}
set cleanList to {}
repeat with i from 1 to count myLines
    if i is not in indexesToDelete then set cleanList's end to myLines's item i
end repeat

-- Combine the filtered list into a string
set myResult to ""
repeat with i from 1 to count cleanList
    if myResult is "" then
        set myResult to cleanList's item i
    else
        set myResult to myResult & return & cleanList's item i
    end if
end repeat

-- Final string
myResult

to split(someText, delimiter)
    set AppleScript's text item delimiters to delimiter
    set someText to someText's text items
    set AppleScript's text item delimiters to {""} --> restore delimiters to default value
    return someText
end split

El script anterior podría reducirse combinando el filtro y los bucles de combinación. Las he dejado como tareas separadas para demostrar mejor sus roles.