¿Mostrar / Ocultar archivos ocultos sin reiniciar el buscador?

Editar: Esto ya no parece funcionar desde El Capitán. killall Finder parece ser la única manera ahora.

Este es mi método actual de El Capitán, que también debería funcionar para Mountain Lion & mayores

set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState & "; killall Finder"

Para Mavericks & Yosemite ...

No es necesario que reinicie Finder, solo actualice las ventanas.

Este Applescript cambiará el estado & actualizar ...

set newHiddenVisiblesState to "YES"
try
    set oldHiddenVisiblesState to do shell script "defaults read com.apple.finder AppleShowAllFiles"
    if oldHiddenVisiblesState is in {"1", "YES"} then
        set newHiddenVisiblesState to "NO"
    end if
end try
do shell script "defaults write com.apple.finder AppleShowAllFiles " & newHiddenVisiblesState


tell application "Finder"
    set theWindows to every Finder window
    repeat with i from 1 to number of items in theWindows
        set this_item to item i of theWindows
        set theView to current view of this_item
        if theView is list view then
            set current view of this_item to icon view
        else
            set current view of this_item to list view

        end if
        set current view of this_item to theView
    end repeat
end tell

Crédito a ganbustein por la mejora de la rutina de ocultar / mostrar

En macOS Sierra, versión 10.12.4 y superior, puede presionar ⌘ + Shift + . _(punto) , para alternar archivos ocultos dentro del Finder.

Edición tardía: esto también funciona en Mojave a partir de b5, 18 de agosto de 2018.