Usando el método incorporado

Según Base de conocimientos de Apple , Numbers admite referencias absolutas :

  

Puedes configurar las referencias de fila y columna en una fórmula para que sean absolutas, de modo que puedas usar la misma fórmula en cualquier otra parte de tu hoja de cálculo sin que las referencias de celda cambien, como lo harían de otra manera.

Para cambiar su fórmula original para usar referencias absolutas, siga estos pasos:

1. Haga doble clic en la celda original para entrar en el modo de edición.
2. Para cada referencia, haga clic en el triángulo; luego marque ambas casillas Conservar fila y Conservar columna.

O, como alternativa al paso 2, puede editar manualmente la referencia para decir e. sol. $A$1 en lugar de A1 .

Los obvios inconvenientes de este método son:

• El método básicamente bloquea la fórmula en un modo que dificulta la reutilización de la misma fórmula en otros lugares donde realmente desea referencias flexibles.

• Si desea copiar muchas fórmulas originales diferentes, necesita repetir el método una y otra vez.

Usando un AppleScript para Copiar fórmulas

Un enfoque más reutilizable sería un simple AppleScript que replica el comando Copiar pero solo copia las fórmulas simples:

on join(cells, delimiter)
  set previousDelimiters to AppleScript's text item delimiters
  set AppleScript's text item delimiters to delimiter
  set resultString to (cells as text)
  set AppleScript's text item delimiters to previousDelimiters
  return resultString
end join

on getSelectedFormulas()
  set tab to character id 9
  set lf to character id 10

  tell application "Numbers"
    tell document 1's sheet 1's table 1
      tell selection range
        set {min, max} to {column 1's address, column -1's address}
        set formulaRows to {}
        repeat with aRow in rows
          set formulaCells to {}
          repeat with aCell in aRow's cells min thru max
            set formulaCells to formulaCells & (aCell's formula)
          end repeat
          set formulaRows to formulaRows & ¬
            my join(formulaCells, tab)
        end repeat
        return my join(formulaRows, lf)
      end tell
    end tell
  end tell
end getSelectedFormulas

on run()
  tell application "Numbers"
    set the clipboard to my getSelectedFormulas()
  end tell
end run

(Nota: Soy el autor de la secuencia de comandos; está bajo la licencia de código abierto ISC .)

Esto también elimina la necesidad de modificar las fórmulas originales.

Vincular el script a un método abreviado de teclado

Para vincular este script a un método abreviado de teclado en Números, abra Automator.app para crear un flujo de trabajo de Automator. Elija la opción El servicio no recibe ninguna entrada en Números , cree un solo paso Ejecutar AppleScript y pegue el código de AppleScript allí.

Guarde el flujo de trabajo con el nombre Copy Formulas , luego abra Preferencias del sistema y haga clic en Teclado, y luego Métodos abreviados de teclado » Servicios » Números » Copiar fórmulas. Configure un método abreviado de teclado; Recomiendo ⌥⇧⌘C porque probablemente lo vayas a usar a menudo con su contraparte, Pegar y Estilo de juego, que ya tiene el acceso directo ⇧⌘V .