Aquí hay un método de AppleScript, que muestra tres tipos diferentes de acciones realizadas en las filas con entradas de celdas duplicadas en columns "A" y "B" (equivalente a cells 1 y 2 ):
use N : application "Numbers"
--------------------------------------------------------------------------------
# PROPERTY VALUES & GLOBAL VARIABLES
property document : a reference to document 1 of N
property sheet : a reference to active sheet of my document
property table : a reference to table 1 of my sheet
global them
--------------------------------------------------------------------------------
# IMPLEMENTATION:
on run
if not (exists my table) then return false
set them to a reference to (every row of my table ¬
where the value of cell 1 = the value of cell 2 ¬
and the value of cell 1 ≠ missing value)
highlight()
---OR:
-- comment()
--OR:
-- delete -- WARNING: permanent!
end run
--------------------------------------------------------------------------------
# HANDLERS:
to highlight()
set the background color of them to ¬
{65535, 65535 / 4, 65535 / 2}
end highlight
to delete
delete them
end delete
to comment()
set the value of cell 3 of them to "SNAP!"
end comment
---------------------------------------------------------------------------❮END❯
He definido tres manejadores, highlight() , comment() y delete , cada uno de los cuales, si se llama, realizará una acción particular en las filas de interés. Actualmente, puede ver en el script algunas líneas dentro de la sección etiquetada IMPLEMENTATION: que lo he configurado actualmente para realizar la acción highlight() , que cambiará el color de fondo de las filas en particular a un tono de rosa que me gusta.
Debajo de esa línea hay comandos que he comentado usando -- , por lo que actualmente permanecen inertes. Cuando no se comenta, el controlador comment() ingresará la palabra "SNAP!" en la tercera columna de cada fila de interés; y el comando delete (note la falta de paréntesis para este) simplemente eliminará las filas por completo. He marcado esto con una advertencia que implica una eliminación permanente, aunque en realidad, puede recordar las filas que volvieron a existir utilizando el elemento de menú integrado Deshacer de la aplicación, o ⌘ < kbd> Z (¡en una base de uno por uno!)
