Crear un servicio con Automator - Probado en macOS Sierra

1. Abrir /Applications/Automator.app
2. Archivo > Nuevo (cmd-N)
   • Elija un tipo de documento: "Servicio".
3. El servicio recibe seleccionados: "archivos o carpetas" en "Finder".
4. En el panel izquierdo navega a: Acciones > Biblioteca > Utilidades > Ejecute AppleScript.
   • Arrastre el elemento "Ejecutar AppleScript" desde el panel de la biblioteca a la izquierda hasta el panel del código fuente a la derecha.
5. Borra completamente el contenido precargado. Pega el siguiente código fuente:

Código fuente de AppleScript

use framework "Foundation" -- Cocoa-AppleScript

on run {input, parameters}
    repeat with thisItem in input
        tell application "Finder"
            if kind of thisItem is "Alias" then -- alias file only
                set parentPath to container of thisItem -- get the folder of this alias
                set {label index:l, comment:c, modification date:m, creation date:cr, original item:origPath, name:n} to properties of (item thisItem)
                if origPath is not missing value then -- not a breaking alias
                    set tagsList to (my tagsFor:(POSIX path of thisItem)) -- get the tags of the alias file (call an AppleScriptObjC handler)
                    delete thisItem -- move this alias to the trash

                    -- ** create an alias file **
                    set newAliasFile to make new alias at parentPath to origPath with properties {comment:c, creation date:cr, original item:origPath, name:n}
                    -- ** set the label ** (0 = no label)
                    if l is not 0 then set label index of newAliasFile to l
                    -- ** set  the tags ** ({} = no tag) 
                    if tagsList is not {} then (my setTags:tagsList forPath:(POSIX path of (newAliasFile as string))) -- call an AppleScriptObjC handler
                    -- ** change the modification date **
                    set modification date of newAliasFile to m
                end if
            end if
        end tell
    end repeat
end run

on tagsFor:posixPath -- Cocoa-AppleScript handler 
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    set {theResult, theTags} to fileURL's getResourceValue:(reference) forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
    if theTags = missing value then return {} -- no tags
    return theTags as list
end tagsFor:

on setTags:tagList forPath:posixPath -- Cocoa-AppleScript handler
    set fileURL to current application's |NSURL|'s fileURLWithPath:posixPath
    fileURL's setResourceValue:tagList forKey:(current application's NSURLTagNamesKey) |error|:(missing value)
end setTags:forPath:

6. Archivo > Guardar (cmd-S): Asígnele un nombre como "Recreación de alias".
7. Abrir preferencias del sistema > Teclado > Accesos directos > Servicios > Archivos y carpetas > Alias recreación, o como lo llames.
   • Asígnele un acceso directo. Como cmd-L se usa para crear un alias (L como en "enlace"), le asigné cmd-alt-ctrl-L.
8. Seleccione uno o varios archivos de alias heredados y procesarlos.
   • Con su acceso directo cmd-alt-ctrl-L.
   • o mediante el menú principal: Finder > Servicios > Archivos y carpetas > Alias de recreación.

Nota : el proceso por lotes es muy transparente y los errores se pueden corregir. Los alias eliminados se mueven a su Papelera. Si ha cometido un error, elija el archivo de alias trashed en cuestión y ejecute Finder > Poner atrás (cmd-backspace). Esto devolverá el archivo a su carpeta principal anterior y abrirá la carpeta principal en una nueva ventana. Luego tiene el alias recreado y el alias original con el sufijo "copiar" uno al lado del otro y puede hacer correcciones si es necesario.