Antes de seguir leyendo: Sé de mayordomo y programas similares. Estoy buscando una forma INTEGRADA de hacer esto sin una aplicación de terceros.
De todos modos, escribí un AppleScript que ejecuta un comando de shell. Quiero mostrar esa salida en la barra de menú en la parte superior ... sin Butler, ¿cómo puedo hacer esto?
En general, sin un programa de terceros, como Growl, no hay una forma integrada para hacer esto.
Sin embargo, puede escribir un script u otro programa como el que encontré aquí que proporciona el servicio de menulet para usted. Estoy seguro de que la integración con Growl sería mucho más fácil de lograr.
No hay una forma integrada de hacer esto en OS X. Sin embargo, al utilizar Growl , puede recibir notificaciones. Aquí hay un script de ejemplo para eso:
--Make sure Growl is running
tell application "System Events"
set isRunning to (count of (every process whose bundle identifier is "com.Growl.GrowlHelperApp")) > 0
end tell
if isRunning then
tell application id "com.Growl.GrowlHelperApp"
set the allNotificationsList to ¬
{"Test Notification", "Another Test Notification"}
--Notifications can be enabled in System Preferences>Growl>Applications>Display Options
set the enabledNotificationsList to ¬
{"Test Notification"}
register as application ¬
"Growl AppleScript Sample" all notifications allNotificationsList ¬
default notifications enabledNotificationsList ¬
-- Set the icon. You can use any icon from any application
icon of application "AppleScript Editor"
notify with name ¬
"Test Notification" title ¬
"Test Notification" description ¬
"This is a test AppleScript notification." application name "Growl AppleScript Sample"
notify with name ¬
"Another Test Notification" title ¬
"Another Test Notification :) " description ¬
"Alas — you won't see me until you enable me..." application name "Growl AppleScript Sample"
end tell
end if
Eso debería mostrar esto:
Ysitambiéntienehabilitadalaotranotificación:
Sedescribentécnicasmásavanzadas
Como AppleScriptObjC es parte de macOS, es posible usar su marco "Foundation" (incluido los métodos de NSMenu) para lograr lo que probablemente no fue posible en 2012.
Encontré un script interesante para crear menús personalizados desde AppleScript; de esto extraje el código adecuado para colocar texto en la barra de menú de macOS . De hecho, solo usa el "título" de un menú para insertar contenido.
Para demostrar esto, implementé un script de diálogo muy básico que solicita a los usuarios la entrada de texto (esperando 6 segundos), que luego se muestra en la barra de menú temporalmente (5 segundos).
Aquí está es:
use framework "Foundation"
use framework "AppKit"
use scripting additions
property StatusItem : missing value
property newMenu : class "NSMenu"
display dialog "Write something:" default answer "" giving up after 6
set myText to text returned of the result
if myText is "" then set myText to "TOOOOO slow … try again !"
set myText to ">> " & myText & " <<"
set bar to current application's NSStatusBar's systemStatusBar
set StatusItem to bar's statusItemWithLength:-1.0
StatusItem's setTitle:myText
set newMenu to current application's NSMenu's alloc()'s initWithTitle:"Custom"
StatusItem's setMenu:newMenu
delay 5
current application's NSStatusBar's systemStatusBar()'s ¬
removeStatusItem:StatusItem
Este código de AppleScript se puede utilizar en cualquier script tuyo. (Su parte de "diálogo" es opcional ...)
user3439894 ayudó a cerrar mi "menú", vea la última línea del script. ¡Muchas gracias!
Lea otras preguntas en las etiquetas display menu-bar applescript