problema con el buscador de Apple

Navega tus respuestas
1

El código de AppleScript: 

on dialogBox(theMessage)
display dialog theMessage default answer "" buttons {"Cancel", "Search"} default button 2 with title "Pick a search engine"
end dialogBox

dialogBox("Google, YouTube, Wiki, Dictionary, Apple, Adobe, or Google Images")

if text returned of result = "Google" then
set search to text returned of dialogBox("Enter Google Search")
tell application "Google Chrome"
    activate
    open location "https://www.google.com/?gfe_rd=cr&ei=4fJgVJ6SM8yD8QfJjYGICA&gws_rd=ssl,cr&fg=1#q=" & search
end tell

else if text returned of result = "YouTube" then
set search to text returned of dialogBox("Enter YouTube Search")
tell application "Google Chrome"
    activate
    open location "https://www.youtube.com/results?search_query=" & search


end tell


else if text returned of result = "Wiki" then
set search to text returned of dialogBox("Enter Word")
tell application "Google Chrome"
    activate
    open location "http://en.wikipedia.org/wiki/" & search


end tell

else if text returned of result = "Dictionary" then
set search to text returned of dialogBox("Enter Word")
tell application "Google Chrome"
    activate
    open location "http://Dictionary.Reference.Com/Browse/" & search


end tell

else if text returned of result = "Apple" then
set search to text returned of dialogBox("Enter Apple Search")
tell application "Google Chrome"
    activate
    open location "http://www.apple.com/search/?q=" & search


end tell

else if text returned of result = "Adobe" then
set search to text returned of dialogBox("Enter Adobe Search")
tell application "Google Chrome"
    activate
    open location "http://www.adobe.com/cfusion/search/index.cfm?term=" & search

end tell

else if text returned of result = "Google Images" then
set search to text returned of dialogBox("Enter Image Search")
tell application "Google Chrome"
    activate
    open location "https://www.google.ca/search?site=imghp&tbm=isch&source=hp&biw=1920&bih=890&q=" & search

end tell
end if

El problema:

En la parte superior, dice ("Google, YouTube, Wiki, Dictionary, Apple, Adobe o Google Images")

Quiero hacerlo para que ponga un signo de interrogación al final, así: ("¿Google, YouTube, Wiki, Diccionario, Apple, Adobe o Google Images?")

Las imágenes de Google tienen un signo de interrogación, pero cuando escribo "Imágenes de Google" en el cuadro de texto, cierra. ¿Puede alguien ayudarme para que pueda escribir imágenes de Google con el signo de interrogación y el programa no se cierra?

    
pregunta Name 10.11.2014 - 21:27

2 respuestas

0

Añadir "¿Imágenes de Google?" a los resultados aceptables para el texto devuelto. 

else if text returned of result is in {"Google Images", "Google Images?"} then

en lugar de: 

else if text returned of result = "Google Images" then

Esto le permitirá ingresar las dos respuestas aceptables en su cuadro de diálogo.

    
respondido por el tron_jones 10.11.2014 - 22:21
0

Le recomendaría que cambie su secuencia de comandos a algo como esto, para evitar todo el copiado / pegado: 

-- this makes it much easier to add a new search engine. The '¬' means the line is continued on the next line.
set searchEngines to { ¬
    {name:"Google", URL:"https://www.google.com/?q="}, ¬
    {name:"YouTube", URL:"https://www.youtube.com/results?search_query="}, ¬
    {name:"Wikipedia", URL:"https://en.wikipedia.org/w/index.php?title=Special%3ASearch&go=Go&search="}, ¬
    {name:"Dictionary", URL:"http://dictionary.reference.com/browse/"}, ¬
    {name:"Apple", URL:"http://www.apple.com/search/?q="}, ¬
    {name:"Adobe", URL:"http://www.adobe.com/cfusion/search/index.cfm?term="}, ¬
    {name:"Images", URL:"https://www.google.ca/search?site=imghp&tbm=isch&source=hp&biw=1920&bih=890&q="} ¬
}

set names to {}
repeat with searchEngine in searchEngines
    set end of names to name of searchEngine
end repeat
choose from list names with prompt "Select a search engine"
if result is false then -- you hit Cancel
    return
else
    set searchEngineName to item 1 of result
end if
repeat with searchEngine in searchEngines
    if name of searchEngine is searchEngineName then
        display dialog "Search " & searchEngineName & ":" buttons {"Cancel", "Search"} default button 2 default answer ""
        open location (URL of searchEngine & text returned of result)
    end if
end repeat
    
respondido por el 0942v8653 10.11.2014 - 23:24

Lea otras preguntas en las etiquetas

Averiguar qué causa el pánico del kernal en Macbook Cambiar el icono de la barra de menú de WhatPulse