¿Un Apple Applescript que se agrega a la etiqueta solo cuando no coincide con parte de la cadena de la etiqueta?

Question

¿Un Apple Applescript que se agrega a la etiqueta solo cuando no coincide con parte de la cadena de la etiqueta?

#1 de jackjr300 (0 votos)

1

Estoy tratando de encontrar una manera de agregar una palabra clave o grupo de palabras / etiquetas / cadenas a un conjunto de pistas seleccionadas de iTunes si no se han agregado. Un caso de uso sería agregar metadatos adicionales en un comentario como (en vivo) o (remezclar).

Si algunas pistas contenían previamente (en vivo) mientras se añadían, entonces no se agregarían, solo los archivos no coincidentes. Por lo tanto, una etiqueta de comentario que contenga (remix) (rápido) (acordeón) (aleatorio) se convertiría en (remix) (rápido) (acordeón) (aleatorio) (en vivo) después. Sin embargo, si se vuelve a aplicar, se omitirá esta pista.

Lo más cercano que puedo encontrar es Smart Append , pero es para Windows solo (siendo JavaScript).

El conocido Doug tiene un adjuntar a la secuencia de comandos de la etiqueta , pero no tiene Cualquier capacidad de detección. Me asomé al código (con el botón derecho del mouse > Mostrar contenido del paquete) y parece que no puedo encajar en mi cabeza editando el script.

¿Alguien sabe de un script existente o una forma de modificar el script existente?

itunes applescript music id3-tag

pregunta ffolke 03.06.2012 - 02:28

1 respuesta

Lea otras preguntas en las etiquetas itunes applescript music id3-tag

¿Por qué los ratones con cable e inalámbricos tienen diferentes aceleraciones? Abra una carpeta en el navegador predeterminado

score 0 · Accepted Answer

Esta secuencia de comandos funciona si la palabra clave está entre paréntesis como en su ejemplo, de lo contrario, la coincidencia parcial será un problema. Ejemplo: " rápido " coincide con " más rápido "

property matchCase : true -- or false -- change according to your needs 

set myTitle to "Append to Comments Tag, if the keyword not exists"
set keywordSeparator to ";" -- keyword separator

tell application "iTunes"
    set sel to selection
    if sel is not {} then -- if tracks are selected...
        set s to "s"
        set x to (length of sel)
        if x is 1 then set s to ""
        set be to (display dialog "Enter keyword to append to the beginning or ending of each selected track's Comments tag:" & return & return & " If more than one keyword, use this character " & keywordSeparator & " as separator." default answer "" buttons {"Cancel", "Beginning", "Ending"} cancel button 1 with title myTitle)
        set appendage to text returned of be
        set buttonOpt to button returned of be is equal to "Ending"
        if appendage is "" then return
        set listOfAppendage to my makeListOfKeywords(keywordSeparator, appendage)
        set oldfi to fixed indexing
        set fixed indexing to true
        repeat with t from 1 to x
            tell contents of item t of sel
                try
                    set tresult to my checkExistKeywords(comment, listOfAppendage, buttonOpt)
                    if tresult is not false then set comment to tresult
                end try
            end tell
        end repeat
        set fixed indexing to oldfi
        activate
        display dialog "Done!" buttons {"OK"} default button 1 with icon 1 with title myTitle giving up after 4
    else
        activate
        display dialog "You must select some tracks first." buttons {"Cancel"} default button 1 with title myTitle
    end if
end tell

on checkExistKeywords(tagValue, tKeywords, tOpt)
    set isAdding to false
    repeat with tKey in tKeywords
        if matchCase then
            considering case
                contents of tKey is not in tagValue
            end considering
        else --Ignore Case
            contents of tKey is not in tagValue
        end if
        if the result then -- no match
            set isAdding to true
            if tOpt then
                set tagValue to tagValue & tKey
            else
                set tagValue to tKey & tagValue
            end if
        end if
    end repeat
    if isAdding then return tagValue
    return false -- nothing to add
end checkExistKeywords

on makeListOfKeywords(tofind, t)
    set ditd to text item delimiters
    set text item delimiters to tofind
    set t to text items of t
    set text item delimiters to ditd
    return t
end makeListOfKeywords