¿Agregar nombres de archivo adjuntos al asunto en mi applecript?

Question

¿Agregar nombres de archivo adjuntos al asunto en mi applecript?

#1 de CJK (2 votos)

0

Soy un novato con applecript. Logré reunir un pequeño script que agregue los archivos seleccionados desde el buscador a un archivo adjunto de correo electrónico como un flujo de trabajo de servicio. Ahora me pegué en el último número. Me gustaría añadir el nombre del archivo al tema. Aquí está la manzana. ¿Alguien podría ayudar?

property mailSubjectPrefix : "Datei(en) für dich: "
property subjAttNameSeparator : ", "
property attachSeparator : "*******"
property attachPrefix : "Anhänge:"

set theSubject to "Datei(en): "
set theContent to "Datei(en) für dich:"
set recipientAddress to {}


tell application "Contacts"

    set recipientAddress to "[email protected]"

end tell




tell application "Finder"
-- Make a list to gather the names of the selected files
set fileAliases to {}
-- Get the selection of the frontmost Finder window
set fileSelection to the selection
-- Iterate of the selection
repeat with fileItem in fileSelection
    copy the fileItem as alias to the end of fileAliases
end repeat
-- Check if the selection is not empty
if the number of items of fileAliases is 0 then
    -- Audible feedback, so the script always does something.
    beep
else
    -- Now talk to mail to create the message
    tell application "Mail"
        set newMessage to make new outgoing message at beginning with properties { content:theContent, visible:true}
        set mailSubject to {}
        -- Set a recipient



        tell newMessage
            make new to recipient at end with properties {address:recipientAddress}



        set MailSubject to fileAliases

        set oTID to AppleScript's text item delimiters
        set AppleScript's text item delimiters to subjAttNameSeparator
        set subject to mailSubjectPrefix & (mailSubject as string)
        set AppleScript's text item delimiters to oTID




        end tell
        -- Attach all the selected files
        repeat with fileAlias in fileAliases
            make new attachment with properties {file name:fileAlias} at after the last paragraph of newMessage

        end repeat




        -- Put Mail in the foreground
        activate


    end tell
end if
end tell

finder applescript

pregunta Markus 20.01.2018 - 23:30

1 respuesta

Lea otras preguntas en las etiquetas finder applescript

¿Cómo puedo hacer "su -c 'cmd' user" de Linux en macOS? ¿Presionar el trackpad táctil de Force es un daño grave?

score 2 · Accepted Answer

Simplemente cambia esta línea:

    set MailSubject to fileAliases

a esto:

    set mailSubject to fileAliases as string

    tell application "Finder" to get insertion location
    set text item delimiters of AppleScript to result

    set mailSubject to rest of text items of mailSubject

ADENDA:

Espero que no observes que el script que presentas en tu pregunta contiene muchos códigos redundantes y / o mal formados. Funciona bien, así que no tiene una gran consecuencia más allá de la estética. Sin embargo, una secuencia de comandos más limpia y bien formada facilita la identificación de errores y, en el caso de secuencias de comandos más largas que realizan más tareas, se ejecutará de manera más eficiente / más rápida.

Teniendo esto en cuenta, me tomé la libertad de volver a escribir su guión, que espero pueda ser útil como herramienta de aprendizaje, o simplemente ser más fácil de entender si desea realizar más cambios. usted mismo.

    property mailSubjectPrefix : "Datei(en) für dich: "
    property subjAttNameSeparator : ", "
    property attachSeparator : "*******"
    property attachPrefix : "Anhänge:"

    set theSubject to "Datei(en): "
    set theContent to "Datei(en) für dich:\n\n"
    set recipientAddress to "[email protected]"


    -- Get the selection of the frontmost Finder window
    -- as a list of aliases
    tell application "Finder"
        set fileAliases to the selection as alias list
        set text item delimiters of AppleScript to insertion location
        set fileNames to rest of text items of (fileAliases as text)
    end tell


    -- Check if the selection is not empty
    if the number of fileAliases is 0 then return beep

    -- Now talk to mail to create the message
    tell application "Mail"
        set text item delimiters of AppleScript to subjAttNameSeparator
        tell (make new outgoing message at beginning ¬
            with properties {content:theContent, visible:true, subject:mailSubjectPrefix & (fileNames as string)})

            -- Add the recipient
            make new to recipient at end with properties {address:recipientAddress}

            -- Attach all the selected files
            repeat with fileAlias in fileAliases
                make new attachment with properties {file name:fileAlias} at after the last paragraph
            end repeat

        end tell

        -- Put Mail in the foreground
        activate
    end tell

Si tiene alguna consulta que necesite aclaración sobre algún punto, no dude en dejar un comentario y le responderé.