aplicación AppleScript como página web de Safari

Question

aplicación AppleScript como página web de Safari

#1 de CJK (1 votos)

0

Actualmente estoy usando una aplicación AppleScript que lanza un sitio web (phpMyAdmin) en Safari. Lo guardo en mi base para facilitar el acceso.

Lo que estoy buscando

Al hacer clic en el ASA (aplicación AppleScript) se abre en la página de safari
Cuando me muevo a una ventana diferente y vuelvo a hacer clic en el ASA, se abrirá la ventana del safari en lugar de volver a abrirla en una nueva ventana / pestaña
Si salgo de ASA, la página de safari se cerrará
Si aparece una X fuera de la pestaña donde está el sitio web, el ASA se cerrará

Si alguien tiene alguna idea de cómo hacerlo, ¡sería genial!

safari applescript

pregunta JBis 15.08.2018 - 17:06

1 respuesta

Lea otras preguntas en las etiquetas safari applescript

Cómo configurar botones adicionales en el mouse 12V - 0,67 Un cargador de pared USB para iPod Classic

score 1 · Accepted Answer

Como han señalado otros usuarios, es probable que no valga la pena mantener la tercera y cuarta viñetas, ya que hace que las dos primeras sean difíciles de implementar:

use S : application "Safari"
property PHPMyAdminURL : "http://xxxxx/ppmya"


on run
    if S is not running then return openPHPMyAdmin()

    set _T to a reference to (every tab of every window of S whose ¬
        name contains "PHPMyAdmin" and ¬
        URL contains "/ppmya")

    if (count _T) > 0 then return viewPHPMyAdmin(_T)

    openPHPMyAdmin()
end run


to openPHPMyAdmin()
    tell S
        if (count windows) = 0 then
            make new document with properties ¬
                {URL:PHPMyAdminURL}
        else
            make new tab at end of tabs of S's window 1 ¬
                with properties ¬
                {URL:PHPMyAdminURL}
            set current tab of S's window 1 to the result
        end if

        activate
    end tell
end openPHPMyAdmin


to viewPHPMyAdmin(T)
    set [T] to T
    set W to the first window of S whose tabs contains T

    set current tab of W to T
    activate S
    set the index of W to 1
end viewPHPMyAdmin

Después de algunos comentarios iniciales de @ user3439894, eliminé el controlador on quit , ya que al intentar usar el script como una aplicación abierta no se implementa de manera efectiva el elemento 2.