¿Cómo uso AppleScript para revelar un archivo en el Finder desde su ruta POSIX?

Navega tus respuestas
6

Estoy intentando crear un fragmento de AppleScript que localiza el fondo de pantalla aleatorio actual y lo muestra en el Finder. Tengo el siguiente fragmento de código que encuentra la ruta POSIX del fondo de pantalla actual como una cadena: 

set plistFolderPath to path to preferences folder from user domain as string
set plistPath to plistFolderPath & "com.apple.desktop.plist"
tell application "System Events"
    tell property list file plistPath
        tell contents
            set thePath to value of property list item "NewChangePath" of property list item "default" of property list item "Background" & "/" & value of property list item "LastName" of property list item "default" of property list item "Background"
        end tell
    end tell
end tell

thePath ahora es una cadena en la forma:

  

/ Volumes / Archive / Widescreen wallpaper / 12345_Name_2560x1440.jpg

(espacios de notas)

Intento revelar esta ruta en FInder, pero todo lo que he probado produce un error: 

tell application "Finder"
    reveal POSIX file of quoted form of thePath (* Error: "Can't get POSIX file of (blah)" *)
end tell

¿Cómo puedo revelar una ruta en Finder en AppleScript cuando todo lo que tengo es su ruta POSIX?

    
pregunta Brant Bobby 02.10.2011 - 18:37

2 respuestas

9

Creo que tu problema es que quoted form . Intenta algo como esto: 

set thePath to POSIX file "/Volumes/Lion HD/Users/ngreenst/Desktop/image.jpg"
tell application "Finder" to reveal thePath

Entonces, solo reveal thePath

    
respondido por el Nathan Greenstein 02.10.2011 - 18:52
4
set p to "/Applications/Utilities/AppleScript Editor.app"

# uses an existing window or makes a new window with your default settings
tell application "Finder"
    reopen # makes a new window if there are no open windows
    activate
    set target of window 1 to (POSIX file p as text)
end tell

# makes a new window that doesn't use your default bounds or view settings
tell application "Finder"
    reveal POSIX file p as text
    activate # focuses the window
end tell
    
respondido por el user495470 03.10.2011 - 06:32

Lea otras preguntas en las etiquetas

¿Cómo comprar Lion OS sin tener que ir a la Mac App Store? ¿Puedo compartir la pantalla con una computadora que no tiene monitor?