Agregar marcadores para varias pestañas en Safari con un atajo de teclado

Puedes usar este Applescript; crea un script de shell que contiene los enlaces para todas las pestañas en la ventana actual de Safari:

-- Set the default folder to Home -> bookmarks
set bookmarkFolder to "/bookmarks"
set username to do shell script "whoami"
set defaultFolder to POSIX file ("/Users/" & username & bookmarkFolder)

-- Initialize the text ot the script.
set cmd to "#!/bin/bash" & linefeed & linefeed

-- Add commands to open all the tabs.
tell application "Safari"
    set n to count of tabs in front window
    repeat with i from 1 to n
        set cmd to cmd & "open -g " & URL of tab i of front window & linefeed
    end repeat
end tell

-- Open/create a file and save the script.

tell me
    activate
    set scriptAlias to choose file name default name "tabset" default location (defaultFolder as alias)
end tell
set scriptPath to quoted form of POSIX path of scriptAlias
set scriptFile to open for access scriptAlias with write permission
set eof scriptFile to 0
write cmd to scriptFile starting at eof
close access scriptFile

-- Change the file attributes to make it double-clickable.
do shell script "chmod 777 " & scriptPath
do shell script "xattr -wx com.apple.FinderInfo '00 00 00 00 00 00 00 00 00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00  00 00 00 00 00 00 00 00' " & scriptPath

La versión original es del Dr. Drang .

He cambiado dos cosas:

• el script permite espacios en blanco en el nombre del archivo
• la carpeta predeterminada es ~/bookmarks

Para ejecutarlo, puedes usar un lanzador (como Quicksilver o Butler ) o envolverlo en un System Service con Automator :

• crea el servicio
  • agregar un elemento Run Applescript
  • seleccione Service receives sin entrada in Safari
  • pegar el Applescript
• crear un acceso directo en System Preferences > Keyboard > Shortcuts > Services
  • ⌘⌥D no funciona si lo usa para alternar la visibilidad del Dock