¿Hay alguna forma de obtener una lista de todos los títulos de las ventanas del programa que se ejecutan actualmente con AppleScript?

Question

¿Hay alguna forma de obtener una lista de todos los títulos de las ventanas del programa que se ejecutan actualmente con AppleScript?

#1 de CJK (1 votos)

0

Estoy buscando escribir un script que muestre una lista de todos los títulos de ventana de todos los programas que se ejecutan actualmente. ¿Hay alguna manera de hacer esto con AppleScript? Intenté ejecutar el siguiente código:

tell application "System Events"
    repeat with theProcess in (every process)
        if background only of theProcess is false then
            say (name of theProcess) as string
        end if
    end repeat
end tell

Lo puse en un archivo llamado lawl.scpt y luego ejecuté lo siguiente en la Terminal:

$ osascirpt lawl.scpt

Sin embargo, solo se detiene por unos segundos, luego sale sin generar nada.

terminal macos applescript script

pregunta Claudiu 26.02.2015 - 06:19

1 respuesta

Lea otras preguntas en las etiquetas terminal macos applescript script

Conecte la pantalla de 27 "a la pantalla Apple Thunderbolt OS X falla "No hay memoria", pero gran parte es gratis

score 1 · Answer 1

Estoy buscando escribir un script que genere una lista de todos los títulos de ventana de todos los programas que se ejecutan actualmente.

El método sencillo de una sola línea para lograr esto en AppleScript es:

    tell application "System Events" to get the name of every window of ¬
        (every process whose background only is false)

Es molesto, esto devuelve una lista anidada, que tendrá que recorrer en un bloque repeat with , o aplanar el nido en una lista simple (que no es demasiado difícil).

La ejecución de AppleScript desde la línea de comandos tiene la ventaja de que los datos devueltos están en formato de texto, que se pueden manipular con bastante facilidad. Incluso puede hacer uso de la línea de comandos desde AppleScript para obtener los beneficios de cada uno:

    do shell script "osascript -e \" ¬
        set text item delimiters to tab
        tell app \\"system events\\" to get name of every window of ¬
            (every process whose background only is false)
        return the result as text \" | egrep -oi -e '[^\t]+'"

    return paragraphs of result

que devuelve una buena lista de texto de títulos de ventanas.

Finalmente, aquí hay un AppleScript formal para hacer el trabajo correctamente, de una manera que le permita conservar la capacidad de referenciar el objeto de la ventana si necesita obtener otras propiedades o manipularlo:

    use application "System Events"

    property R : {WindowTitle:missing value, AttachedToProcess:missing value}

    set WindowList to {}

    set P to a reference to (every process whose background only is false)

    repeat with proc in P
        set [proc] to proc
        set W to (a reference to every window of proc)

        repeat with _w in W
            set [_w] to _w

            copy R to end of WindowList
            tell last item of WindowList
                set its WindowTitle to title of _w
                set its AttachedToProcess to name of proc
            end tell
        end repeat
    end repeat

    return WindowList

La lista resultante es una lista de registros que tienen la estructura de property R . Cada registro representa una sola ventana, que contiene el título de la ventana y el nombre del proceso al que pertenece, por ejemplo. %código%. De esta manera, es fácil hacer cosas con la ventana, como:

    set TheWindow to item 2 of WindowList --> {WindowTitle:"...", AttachedToProcess:"..."}

    tell process named (TheWindow's ProcName) to ¬
        tell window named (TheWindow's WindowTitle) to ¬
            set [focused, position, size] to [true, {0, 0}, {400, 777}]