Transferir recordatorios de iCal al calendario de Google

Por lo que entiendo, los recordatorios no son transferibles. Cada servicio los programa de manera diferente y no hay forma (aparte de copiar / pegar texto) transferirlos fácilmente. Espero que esto ayude.

Esta secuencia de comandos al menos ayudará con la exportación de recordatorios:

#!/usr/bin/osascript

tell application "Reminders"
    set todo_accounts to every account
    -- accounts have lists. loop thru accounts to get their lists.
    repeat with i from 1 to length of todo_accounts
        tell account i
            set todo_lists to get every list
            -- lists have reminders. loop thru lists to get their reminders
            repeat with j from 1 to length of todo_lists
                tell list j
                    set todos to (get reminders)
                    -- if there are no reminders for a list, then ignore the list
                    if length of todos is greater than 0 then
                        -- Write out the name of the list
                        do shell script "echo " & (quoted form of (get name)) & " >> ~/Desktop/todos.txt"
                        -- loop thru the reminders to get properties
                        repeat with k from 1 to length of todos
                            set this_todo to item k of todos
                            if (this_todo is not completed) then
                                do shell script "echo [  ] " & (quoted form of (get name of this_todo)) & " >> ~/Desktop/todos.txt"
                            end if
                        end repeat
                    end if
                end tell
            end repeat
        end tell
    end repeat
end tell