AppleScripting QuickTime Pro 7 para exportar archivos .png

Aquí está mi script para exportar a PNG escrito para Snow Leopard. Puede ajustarse a sus necesidades con la suficiente facilidad ...

EDITAR: Aquí está su código que incorpora el código original que publiqué. Esto funciona como lo describiste, querías que el applet funcionara.

property type_list : {"M4V ", "mpg4"} -- e.g.: {"PICT", "JPEG", "TIFF", "GIFf"} 
property extension_list : {"mp4", "m4v", "mpg"} -- e.g.: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property typeIDs_list : {"public.mpeg-4"} -- e.g.: {"public.jpeg", "public.tiff", "public.png"}

on open these_items
    repeat with i from 1 to the count of these_items
        set this_item to item i of these_items
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try

            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end open

-- this sub-routine processes folders 
on process_folder(this_folder)

    # Debug
    tell application "Finder" to set f to name of this_folder
    log "Processing folder: " & f

    set these_items to list folder this_folder without invisibles
    repeat with i from 1 to the count of these_items
        set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try

            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end process_folder

-- this sub-routine processes files 
on process_file(this_item)
    tell application "QuickTime Player 7"
        set play movie from beginning when opened to false

        open this_item

        tell front document

            # Remove extension from filename
            set n to (this_item as string)
            set n to text 1 thru ((offset of "." in n) - 1) of n

            # Use .png since it will be overwritten later on...
            set xFileStart to n & "_start.png"
            set xFileEnd to n & "_end.png"

            # Positions (in seconds) in video to stop and take frames
            set sPos to 1
            set ePos to 1

            # Move for start frame
            set current time to (time scale * sPos)
            export to xFileStart as BMP using default settings with replacing

            # Move for end frame
            set current time to (duration - (time scale * ePos))
            export to xFileEnd as BMP using default settings with replacing

            close
        end tell

        # Do the actual conversion to PNG
        tell application "Image Events"
            set bmpFile to open file xFileStart
            save bmpFile as PNG
            set bmpFileEnd to open file xFileEnd
            save bmpFile as PNG
        end tell

    end tell
end process_file

El Applescript que está utilizando para Quicktime es incorrecto y le está pidiendo que haga un comando que sea de las adiciones estándar. Yo camino a

QuickTime no entenderá esto y fallará. Del mismo modo:

set frameOne of this_item to track (beginning)
set frameEnd of this_item to track (end)

QT no sabrá lo que comienza y final son

Debería leer el diccionario de Quicktime 7 para comprender su sintaxis.

En el Editor de secuencias de comandos, vaya al menú Ventana- > Biblioteca

Esto abrirá la ventana de la biblioteca del diccionario de aplicaciones.

Dudo que QT7 esté en la lista, así que vaya al buscador y localice QT7. Normalmente está en la carpeta / Aplicaciones / Utilidades .

Arrástrelo a la ventana de la biblioteca del diccionario de aplicaciones.

Luego haz doble clic en él.

Se abrirá un diccionario. Léalo para comprender lo que QT7 puede entender.

Ahora el Script.

No he tocado ninguno de ustedes chequeo de archivos.

Lo que he cambiado es el contenido del controlador process_file () . Y agregue algo de Objective-C para simplificar la obtención de la ruta y el nombre del archivo.

No te preocupes demasiado por las cosas de Objective -c. Aún puedes usar Applescript convencional que entiendes si solo quieres reemplazarlo.

Las partes importantes son:

Configuración de la posición del cabezal de reproducción y la exportación de la película. Debido a que estamos utilizando BMP, solo se exportará el fotograma actual.

Observe que establezco el inicio en 0 y el final en la duración completa de la película - 20.

Por lo que entiendo las mediciones son en milisegundos. Por lo tanto, tener -20 del final no debería hacer mucha diferencia en lo que captura. Pero hago esto porque uno de mis videos de prueba tuvo problemas para obtener el último fotograma en toda su duración. Recibí un error que decía un marco inválido. Cambiándolo ligeramente antes de resolver el problema.

También uso un poco de línea de comandos para convertir el bmp a un png.

Nuevamente, para simplificar las cosas (al menos para mí) puedes usar tu propio método aquí, si lo deseas.

use scripting additions
use framework "Foundation"



(* TO FILTER FOR SPECIFIC FILES, ENTER THE APPROPRIATE DATA IN THE FOLLOWING LISTS: *)
property type_list : {"M4V ", "mpg4"} -- e.g.: {"PICT", "JPEG", "TIFF", "GIFf"} 
property extension_list : {"mp4", "m4v", "mpg"} -- e.g.: {"txt", "text", "jpg", "jpeg"}, NOT: {".txt", ".text", ".jpg", ".jpeg"}
property typeIDs_list : {"public.mpeg-4"} -- e.g.: {"public.jpeg", "public.tiff", "public.png"}


-- This droplet processes files dropped onto the applet 
on open these_items
    repeat with i from 1 to the count of these_items
        set this_item to item i of these_items
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end open

-- this sub-routine processes folders 
on process_folder(this_folder)
    set these_items to list folder this_folder without invisibles
    repeat with i from 1 to the count of these_items
        set this_item to alias ((this_folder as Unicode text) & (item i of these_items))
        set the item_info to info for this_item
        if folder of the item_info is true then
            process_folder(this_item)
        else
            try
                set this_extension to the name extension of item_info
            on error
                set this_extension to ""
            end try
            try
                set this_filetype to the file type of item_info
            on error
                set this_filetype to ""
            end try
            try
                set this_typeID to the type identifier of item_info
            on error
                set this_typeID to ""
            end try
            if (folder of the item_info is false) and (package folder of the item_info is false) and (alias of the item_info is false) and ((this_filetype is in the type_list) or (this_extension is in the extension_list) or (this_typeID is in typeIDs_list)) then
                process_file(this_item)
            end if
        end if
    end repeat
end process_folder

-- this sub-routine processes files 
on process_file(this_item)
    tell application "QuickTime Player 7"
        set thisDoc to open this_item -- This will open the file in Quicktime
        tell thisDoc
            set xFolder to its path
            set duro to its duration

        end tell

    end tell

    -->> Objective - c to get the name and file path
    set xFolder to current application's NSString's stringWithString:(xFolder as string)

    set file_path to ((xFolder's stringByDeletingLastPathComponent) as string) & "/"


    set file_name to xFolder's lastPathComponent

    set file_name to (file_name's stringByDeletingPathExtension) as string
    --<<


    tell application "QuickTime Player 7"
        tell thisDoc
            set current time to 0
            set xFileStart to file_path & file_name & "_start.png"

            export track 1 to xFileStart as BMP using default settings with replacing
            delay 1
            do shell script ("sips -s format png " & (quoted form of xFileStart)) -- convert to png
            set current time to (duro - 20)
            set xFileEnd to file_path & file_name & "_end.png"
            export track 1 to xFileEnd as BMP using default settings with replacing
            delay 1
            do shell script ("sips -s format png " & (quoted form of xFileEnd)) -- convert to png
        end tell
        close thisDoc
    end tell
end process_file