¿AppleScript para reiniciar en Bootcamp?

Navega tus respuestas
-1

He intentado usar un AppleScript para reiniciar en Windows. Sin embargo, no va bien, ya que cuando lo probé por primera vez, apareció una pantalla blanca al inicio y no desapareció. Un reinicio duro reiniciado a Yosemite. He guardado este script como una aplicación y en mi Dock para reinicio instantáneo, pero ha sido decepcionante.

Aquí está el script: 

set adminpass to "MYPASSWORDWENTHERE"

tell application "Finder"
    set iconPath to (get name of startup disk) & ":Applications:Utilities:Boot Camp Assistant.app:Contents:Resources:DA.icns" as alias
end tell

set askRestart to display dialog "Restart in Windows?" buttons {"Cancel", "Restart"} default button 1 with icon iconPath
set doRestart to button returned of askRestart

if doRestart is equal to "Cancel" then
    quit
end if

if doRestart is equal to "Restart" then
    do shell script "bless -mount /Volumes/BOOTCAMP/ -legacy -setBoot -nextonly; shutdown -r now" password adminpass with administrator privileges
end if

¿Puede alguien ayudarme a que esto funcione?

    
pregunta JesusGeek35 26.03.2015 - 02:48

2 respuestas

0
do shell script "bless -mount /Volumes/WINDOWS/ -legacy -setBoot -nextonly" with administrator privileges
do shell script "shutdown -r now" with administrator privileges

Reemplaza WINOWS con el nombre de tu partición de bootcamp.

Fuente: Lifehacker.com

    
respondido por el Kevin Grabher 26.03.2015 - 17:25
0

Probé esto usando Yosemite y funciona. Supongo que está haciendo un arranque de BIOS para Windows. Si está realizando un arranque EFI, entonces esta secuencia de comandos probablemente no funcionará. El arranque de BIOS es la forma tradicional en que BootCamp instala Windows en Mac. Agregué un botón adicional para permitir cambiar el sistema operativo predeterminado a Windows.

¿Es consciente de que puede mantener presionada la tecla Alt / Opción al inicio para seleccionar qué sistema operativo arrancar? También asumo, ¿sabe que el sistema operativo de arranque predeterminado puede seleccionarse desde las Preferencias del sistema en OS X y el Panel de control en Windows?

También puede instalar el gestor de arranque gratuito rEFInd . Este producto puede producir un menú de inicio opcional cada vez que inicie (o reinicie) su Mac. A continuación, puede seleccionar qué sistema operativo iniciar. Si está interesado, avíseme y le ayudaré a configurar REFInd. 

set output to do shell script "diskutil list /dev/disk0"
repeat with row in paragraphs in output
    if row contains "Microsoft Basic Data" then
        set slice to last word in row

        set adminpass to "MYPASSWORDWENTHERE"

        tell application "Finder"
            set iconPath to (get name of startup disk) & ":Applications:Utilities:Boot Camp Assistant.app:Contents:Resources:DA.icns" as alias
        end tell

        try
            set askRestart to display dialog "Restart in Windows?" buttons {"Cancel", "Once", "Always"} default button 1 with icon iconPath
        on error
            exit repeat
        end try
        set doRestart to button returned of askRestart

        if doRestart is in {"Restart", "Once", "Always"} then
            set command to "bless --device /dev/" & slice & " --legacy --setBoot"
            if doRestart is in {"Restart", "Once"} then
                set command to command & " --nextonly"
            end if
            set command to command & "; shutdown -r now"
            try
                do shell script command password adminpass with administrator privileges
            end try
        end if

        exit repeat
    end if
end repeat
    
respondido por el David Anderson 31.03.2015 - 17:05

Lea otras preguntas en las etiquetas

Mac mini como “enrutador” Audio de entrada / salida combinado con un conector de 3,5 mm con 4 clavijas - Macbook Pro (2015)