¿Cómo adjuntar un archivo a Outlook desde la terminal usando Applescript?

Question

¿Cómo adjuntar un archivo a Outlook desde la terminal usando Applescript?

#1 de Hurston (1 votos)

0

Estoy escribiendo un Applescript para poder adjuntar un archivo a Outlook desde el terminal de la siguiente manera:

$ attachToOutlook myreport.xlsx

Donde attachToOutlook tiene un alias de osascript /path/to/my/script/attach

Esta es mi implementación actual:

on run argv
  tell application "Microsoft Outlook"
    set theContent to ""
    set theAttachment to item 1 of argv
    set theMessage to make new outgoing message with properties {subject: ""}
    tell content
      make new attachment with properties {file: (item 1 of argv )} at the end of theMessage
    end tell
    open theMessage -- for further editing
  end tell
end run

pero me aparece el siguiente error:

attach:263:264: script error: Expected expression, etc. but found “:”. (-2741)

¿Cómo puedo solucionar esto?

terminal ms-office applescript

pregunta ILikeTacos 23.10.2017 - 19:55

1 respuesta

Lea otras preguntas en las etiquetas terminal ms-office applescript

launchd socket input cmd + [num] no cambia la pantalla para ir a la aplicación en modo de pantalla completa

score 1 · Accepted Answer

Un par de cuestiones. Primero, debe hacer el nuevo archivo adjunto al mensaje, no al contenido. En segundo lugar, el archivo adjunto debe ser un archivo posix. En tercer lugar, no puede simplemente enviar un nombre de archivo, debe indicar a Outlook dónde se encuentra el archivo incluyendo la ruta completa.

He escrito mi propia versión incluida aquí, agregando el tema y el contenido como variables pasadas a través de la línea de comandos.

Nota: llame con lo siguiente, reemplazando con el nombre de cuenta real.

osascript testterm.scpt '/Users/<user name>/Desktop/test2.rtf' 'Test Subject' '<p>This is a test content for an email test</p>'

Código AppleScript en testterm.scpt :

on run argv
    set theAttachment to item 1 of argv
    set theAttachment to theAttachment as POSIX file--convert to posix file
    set theSubject to item 2 of argv
    set theContent to item 3 of argv
    tell application "Microsoft Outlook"
        set theMessage to make new outgoing message with properties {subject:theSubject, content:theContent}
        tell theMessage--tell theMessage (not theContent) to add the attachment
            make new attachment with properties {file:theAttachment}
        end tell
    open theMessage
    end tell
end run