El uso de AppleScript para alternar el uso compartido de Internet no funciona

Question

El uso de AppleScript para alternar el uso compartido de Internet no funciona

#1 de TGYK (1 votos)
#2 de Alistair McMillan (0 votos)

0

Estoy usando una aplicación AppleScript para activar la opción de compartir en Internet desde 'Pref. del sistema > Compartiendo '. Yo trabajo en MacOs 10.9.4. Encontré este script en un foro y lo estoy usando. Esto funciona bien, cuando la ventana de Preferencias del Sistema está abierta. Sin embargo, cuando se cierra la ventana de Preferencias del sistema, la secuencia de comandos abre la ventana de Preferencias del sistema y luego muestra este mensaje de error:

 System Events got an error: Can’t get menu item \"Sharing\" of menu \"View\" of menu bar 1 of process \"System Preferences\"." number -1728 from menu item "Sharing" of menu "View" of menu bar 1 of process "System Preferences"

Este es el código para el script

tell application "System Preferences"
        activate
    end tell
    tell application "System Events"
        activate
        tell process "System Preferences"

            click menu item "Sharing" of menu "View" of menu bar 1
            delay 2
            tell window "Sharing"...
//code after this

No soy competente en AppleScript, pero solo necesito usar este para obtener un método abreviado de teclado para alternar el uso compartido de Internet. Además, el foro del que lo obtuve dice que los demás usuarios pueden usar el script. Me pregunto si tiene algo que ver con MAcOs 10.9

mavericks system-prefs applescript internet-sharing

pregunta code_enthu 04.08.2014 - 22:00

2 respuestas

Lea otras preguntas en las etiquetas mavericks system-prefs applescript internet-sharing

Cómo salir del modo de recuperación en un iPhone con jailbreak Macbook 2010 con OS X 10.9: problema de "Dangling Thumbs" al escribir

score 1 · Answer 1

Puede usar este código para activar el uso compartido con configuraciones que ya estaban allí:

tell application "System Preferences"
    activate
    set current pane to pane "com.apple.preferences.sharing"
end tell
tell application "System Events" to tell process "System Preferences"

    --find lock and click it if it is not unlocked
    repeat with x in buttons of window "Sharing"
        try
            if (value of attribute "AXTitle" of x) is equal to "Click the lock to make changes." then
                click x
            end if
        end try
    end repeat
    delay 5

    --find the checkbox for Internet Sharing and select the row so script can enable sharing through ethernet
    repeat with r in rows of table 1 of scroll area 1 of group 1 of window "Sharing"
        if (value of static text of r as text) starts with "Internet" then
            select r
        end if
    end repeat
    delay 2

    --enable Internet Sharing
    repeat with r in rows of table 1 of scroll area 1 of group 1 of window "Sharing"
        if (value of static text of r as text) starts with "Internet" then
            set sharingBool to value of checkbox of r as boolean
            select r
            if sharingBool is false then click checkbox of r
        end if
    end repeat
    delay 2

    if (exists sheet 1 of window "Sharing") then
        click button "Start" of sheet 1 of window "Sharing"
    end if
    delay 2

end tell
ignoring application responses
    tell application "System Preferences" to quit
end ignoring

Espero que esto ayude!

score 0 · Answer 2

0

Otra forma de abrir las Preferencias del sistema en el panel Compartir es ...

tell application "System Preferences"
    activate
    set current pane to pane id "com.apple.preferences.sharing"
end tell

Esto funcionará si las Preferencias del sistema están abiertas o no.

respondido por el Alistair McMillan 05.08.2014 - 01:06