¿Puedo grabar la pantalla de mi Mac con un atajo de teclado?

Espacio , creo (mientras que la nueva ventana de grabación de pantalla en QuickTime Player es la más avanzada). No estoy seguro de parar, ⌃ + hice clic en el icono de QuickTime Player Dock y seleccioné "Detener grabación". La próxima vez que lo intenté, recibí una ventana emergente de instrucciones cuando presioné Espacio que me dijo que presionara el botón en la barra de menú para detener. ¿Eso funcionó? ¡Pero ScreenFlow hace muchísimo!

BTW, ⌃ + ⌘ + N mientras QuickTime Player is Frontmost abre una nueva pantalla de grabación, si no necesita automatizar El proceso desde otro lugar.

Se incluye la fuente de un droplet de AppleScript que se puede usar para transcodificar archivos de video.

Necesitará una instalación moderna de ffmpeg, como la que puede obtener al instalar HomeBrew y ejecutar "brew ffmpeg".

Esta conversión no se ha optimizado para la velocidad, sino para la calidad.

No se ha incluido la eliminación de archivos de origen en esta configuración.

No necesitarás el autocropping. Probablemente no querrá la conversión al audio AC3 de 6 canales.

Es probable que la mayoría de las cosas que sueltes en esto terminen con un mayor tamaño de archivo después de la transcodificación, pero esto te mostrará cómo se puede configurar una gota para convertir videos.

Tengo un montón de estos, pero creo que esto procesará casi todo lo que descargues de YouTube. Si puede obtener un archivo .m2ts sin cifrado de copia de un Blu-Ray (como el que MakeMKV puede proporcionarle), es posible que le muestre lo que esto puede hacer.

property temppath : "/private/tmp/"
property startnum : 0
property newline : ASCII character 10
property tmpfile : "/tmp/execme.command"

on open the_items
    my convert_Video(the_items)
end open

on convert_Video(the_items)
set theshellscript to ""
repeat with the_item in the_items
    set the_item to the_item as alias
    try
        tell application "Finder"
            set sost to (container of the_item) as string
        end tell
        set pos_filepath to POSIX path of sost
    end try
    set this_filepath to (the_item as string)

    if last character of this_filepath is ":" then
        tell me to set it_is_a_folder to true
    else
        set it_is_a_folder to false
    end if
    set thesourcename to (name of (info for the_item))
    set namepart to (name extension of (info for the_item))
    set the_source_file to POSIX path of this_filepath
    --display dialog the_source_file
    --set thesourcename to replace_chars(thesourcename, " ", "_")
    set newname to replace_chars(thesourcename, namepart, "m4v")
    set autocrop to (do shell script "/usr/local/bin/ffmpeg -i" & space & (quoted form of the_source_file) & space & "-t 44 -vf cropdetect -f null - 2>&1 | awk '/crop/ { print $NF }' | tail -1")
    try
        set theshellscript to the theshellscript & "/usr/local/bin/ffmpeg" & space & "-i" & space & (quoted form of the_source_file) & space & "-pix_fmt yuv420p -c:v libx264 -preset slow -tune film -vf \"" & autocrop & "\" -c:a ac3 -ac 6 -ab 640k -crf 18 -x264opts keyint=40:bitrate=2400:qpmin=8:qpmax=28:qpstep=4" & space & (quoted form of (pos_filepath & newname)) & ";/bin/echo '

==========================

" & newname & space & "FINISHED!" & "

==========================

';"
            on error onerr
                activate
                display dialog onerr
            end try

end repeat
set theshellscript to theshellscript & "mv" & space & (quoted form of tmpfile) & space & (quoted form of (POSIX path of (path to trash)))
do shell script "echo " & quoted form of theshellscript & " > " & tmpfile
repeat
    try
        do shell script "chmod +x " & tmpfile
        do shell script "open -a Terminal.app" & space & tmpfile
        exit repeat
    on error
        delay 1
    end try
end repeat
end convert_Video

on replace_chars(this_text, _bad, _good)
    set AppleScript's text item delimiters to the _bad
    set the item_list to every text item of this_text
    set AppleScript's text item delimiters to the _good as string
    set this_text to the item_list as string
    set AppleScript's text item delimiters to ""
    return this_text
end replace_chars

on run
    set the_items to ((choose folder) as list)
    convert_Video(the_items)
end run