Mac, automatización de las búsquedas de itunes de una lista de palabras?

Question

Mac, automatización de las búsquedas de itunes de una lista de palabras?

#1 de unlocked2412 (2 votos)

-1

Me gustaría realizar varias búsquedas en la aplicación iTunes mac, deteniéndome hasta que luego reanude la próxima búsqueda. Tengo una lista de búsquedas que quiero realizar.

Entonces, o bien necesito producir algún tipo de secuencia de comandos de automatización, lo que me dará algún tipo de botón para tocar para reanudar.

O necesito algo que me permita pegar el siguiente elemento en mi lista, etc.

Básicamente, estoy tratando de ahorrar un poco de esfuerzo al tener que escribir las palabras cada vez.

He echado un vistazo a automator, alfred, hazel y al editor de AppleScript. Pero no creo que ninguno de estos funcionará.

copy-paste applescript automation automator

pregunta Jules 07.06.2017 - 22:40

1 respuesta

Lea otras preguntas en las etiquetas copy-paste applescript automation automator

Duplicar un disco entero iPhone no se enciende, perdió toda la información de recuperación

score 2 · Answer 1

Puedes hacer algo así en Applescript. iTunes proporciona un comando search que proporciona una referencia a una pista.

Así que puedes usar este comando en un bucle que:

Muestra un cuadro de diálogo que solicita los términos de búsqueda.
Un cuadro de diálogo de selección múltiple muestra las coincidencias de iTunes para este término de búsqueda.
Selecciona la pista deseada de este diálogo. Luego puedes jugar tu cola personalizada de una en una.

Código:

set lst_tracks to {}
try
    repeat
        display dialog "Please enter search terms" buttons {"Stop Searching", "Search More"} default button 2 cancel button 1 default answer ""
        set the_text to (text returned of result)
        tell application "iTunes"
            set end of lst_tracks to my GetiTunesTrack(the_text)
        end tell
    end repeat
end try
if lst_tracks ≠ {} then
    set the_result to (display dialog "Start Playing?" buttons {"No", "Yes"} default button 2 cancel button 1)
    set the_button to button returned of the_result
    if the_button = "Yes" then
        try
            repeat with i in lst_tracks
                tell application "iTunes"
                    set the_track to (contents of i)
                    set track_name to name of the_track
                    play the_track
                    set the_result to (display dialog "Playing: " & track_name buttons {"Stop", "Next Track"} default button 2 cancel button 1)
                end tell
            end repeat
        on error
            tell application "iTunes" to stop
        end try
    end if
end if
display dialog "Finish"

on GetiTunesTrack(search_str)
    local lst_names

    set lst_names to {}
    tell application "iTunes"
        set lst_results to (search library playlist 1 for search_str)

        repeat with item_ref in lst_results
            set end of lst_names to name of item_ref
        end repeat

        set the_selection to item 1 of (choose from list lst_names with prompt "Choose a Track" default items (item 1 of lst_names))
        set the_track to first track of library playlist 1 whose (name is the_selection)
        return the_track
    end tell
end GetiTunesTrack